仅在打开时保存工作簿的条件

Question

嗨，我所有的代码可以自动完成一个工作簿

Private Sub Workbook_Open()



Application.OnTime Now + TimeValue("00:01:00"), "Save1"



End Sub

Sub Save1()
Application.DisplayAlerts = False
ThisWorkbook.Save
Application.DisplayAlerts = True

Application.OnTime Now + TimeValue("00:01:00"), "Save1"
End Sub

问题，现在它可以不断开放以保存。任何人都知道该语法是什么才能在打开时才保存的？

Answer 1

您的问题是您永远不会停止计时器 - 即使您关闭了工作簿，它也会保持活跃。分钟结束后，VBA想要调用当前尚不可用的sub（save1）（由于工作簿关闭），因此VBA要求Excel打开文件，以便它可以执行例程。

如果您以某种方式添加了工作簿，则无济于事，因为当时，它 已经再次打开。

您需要做的是关闭工作簿时停止计时器。该事件是workbook_beforeclose。现在停止在VBA中停止计时器有点棘手：您再次调用application.intime -Method，您必须提供当时设置时发布时发出的确切参数：例程和的名称需要匹配的时间。唯一的区别是，您将第四参数（Schedule）设置为false。

结果，您的代码需要跟踪在最后一次呼叫ontime的时间上提供的时间。查看以下代码：

在工作簿模块中：

Private Sub Workbook_Open()
    StartTimer
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    StopTimer
End Sub

在常规代码模块中：

Option Explicit

Dim FireTime As Variant     ' This holds the time when Ontime was called the last time

Sub StartTimer()
    FireTime = Now + TimeValue("00:01:00")
    Application.OnTime FireTime, "Save1"
    ' ThisWorkbook.Sheets(1).Cells(1, 1) = FireTime
End Sub

Sub StopTimer()
    If Not IsEmpty(FireTime) Then
        Application.OnTime FireTime, "Save1", , Schedule:=False
        FireTime = Empty
    End If
End Sub

Sub Save1()
    Debug.Print "tick"
    ' put your actions here, eg saving 
    StartTimer  ' Schedule the next Timer event
End Sub

Answer 2

您可以使用：

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.OnTime Now + TimeValue("00:01:00"), "Save1",, False
End Sub