尝试抓住Xquery不工作的Marklogic

Question

我正在使用以下代码将与指定集合有关的文档从一个数据库复制到另一个数据库。 在我的尝试块中，我将在成功复制后返回以删除所有文档。在捕获中只是为了打印例外。 但这给了我一个我无法弄清楚的语法错误。有人可以帮我吗？

xquery version "1.0-ml";
for $doc in cts:search(doc(), cts:collection-query('Test'))
let $docuri := $doc/base-uri()
let $collections := xdmp:document-get-collections($docuri)
let $permissions := xdmp:document-get-permissions($docuri)
let $document-insert-options := 
  <options xmlns="xdmp:document-insert">  
    <permissions>{$permissions}</permissions>z
    <collections>{
        <collection>{$collections}</collection>
        }
        </collections> 
  </options>
let $db-name := "Final"  
let $invoke-function-options := 
  <options xmlns="xdmp:eval">
    <database>{ xdmp:database($db-name) }</database>
    <commit>auto</commit>
  </options>
return
try {
  xdmp:invoke-function(
   function(){ xdmp:document-insert($docuri, $doc, $document-insert-options)},
   $invoke-function-options
 ); 
  return xdmp:document-delete($doc)
 }
catch ($exception) {
"Problem loading file, received the following exception: ",
$exception }

Answer 1

迈克尔和罗布都有好积分，但还有一些问题。

MarkLogic确实抱怨$ document-insert-options中的额外“ z”。摆脱这一点。

MarkLogic还将抱怨您将您传递给$ doc而不是$ docuri的事实：xdmp：document-delete。因此，也改变了这一点。

最后是半颜料。 Marklogic确实支持了这一点，但仅在顶级。使用Michael建议，插入和删除可能并行发生。使用Rob提出的额外的“让$ _：='，然后删除';'将导致Marklogic首先插入，然后删除第二。我认为这就是您所追求的。

从QC（'Fab'会做的）对随机数据库进行以下操作，在我的末端正常工作：

xquery version "1.0-ml";

xdmp:document-insert('/test.json', object-node{"foo":"bar"}, map:entry("collections", "Test"))
;
xquery version "1.0-ml";
for $doc in cts:search(doc(), cts:collection-query('Test'))
let $docuri := $doc/base-uri()
let $collections := xdmp:document-get-collections($docuri)
let $permissions := xdmp:document-get-permissions($docuri)
let $document-insert-options := 
  <options xmlns="xdmp:document-insert">  
    <permissions>{$permissions}</permissions>
    <collections>{
        <collection>{$collections}</collection>
        }
        </collections> 
  </options>
let $db-name := "Documents"  
let $invoke-function-options := 
  <options xmlns="xdmp:eval">
    <database>{ xdmp:database($db-name) }</database>
    <commit>auto</commit>
  </options>
return
try {
  let $_ := xdmp:invoke-function(
   function(){ xdmp:document-insert($docuri, $doc, $document-insert-options)},
   $invoke-function-options
  )
  return xdmp:document-delete($docuri)
 }
catch ($exception) {
"Problem loading file, received the following exception: ",
$exception }

HTH！

Answer 2

什么是错误？

此块看起来错误：

let $document-insert-options := 
 <options xmlns="xdmp:document-insert">  
  <permissions>{$permissions}</permissions>z
  <collections>{
    <collection>{$collections}</collection>
    }
  </collections> 
 </options>

您有一个z在＆lt;/permissions＆gt;之后浮出水面，这可能会破坏选项节点的架构验证。

这也可能是错误的：

catch ($exception) {
 "Problem loading file, received the following exception: ",
$exception }

您可能需要明确返回这样的序列：

catch ($exception) {
 ("Problem loading file, received the following exception: ",
$exception)}

这对我来说似乎也很奇怪：

try {
 xdmp:invoke-function(
  function(){ xdmp:document-insert($docuri, $doc, $document-insert- 
  options)},
  $invoke-function-options
 ); 
 return xdmp:document-delete($doc)
}

通过尝试使用>;的多态交易来打破flwor。

而是尝试：

try {
 let $_ := xdmp:invoke-function(
  function(){ xdmp:document-insert($docuri, $doc, $document-insert- 
  options)},
  $invoke-function-options
 )
 return xdmp:document-delete($doc)
}

Answer 3

Xquery没有分号限制的语句，也没有任何以“返回”开头的指令或表达式。

  xdmp:invoke-function(
   function(){ xdmp:document-insert($docuri, $doc, $document-insert-options)},
   $invoke-function-options
 ); 
  return xdmp:document-delete($doc)
 }
catch ($exception) {
"Problem loading file, received the following exception: ",
$exception }

用逗号（“，”）替换“; return”。

Marklogic也可能有特殊的规则来调用具有副作用的功能；我不知道那个领域。