我想在Java处理中以圆形运动移动一个正方形

Question

这是一个学校项目，因此我不能使用很多诸如翻译或旋转之类的功能。我必须使用基本三角学来做到这一点。因此，我制作了一个正方形，我需要它以360度的圆形运动移动，其点恒定且不动。

               float rotX,rotY;
               size(500,500);

               fill(#B71143);
               int rectX=width/4;
               int rectY=height/10;
               int rectSize=30;
               angle=angle+0.1;
               //rotX=rectX*cos(angle)-rectY*sin(angle);
               //rotY=rectX*cos(angle)+rectY*sin(angle);

               square(rotX,rotY,rectSize);

Answer 1

至少就三角学部分而言，您是如此亲密。

在处理方面，您只缺少setup（） and draw（）它将绘制一个帧（一旦您取消注册rotx的作业，roty，roty < /code>和初始化Angle to 0）

这是您的代码，上面的注释：

float rotX, rotY;
float angle = 0;

void setup() {
  size(500, 500);

  fill(#B71143);
}

void draw() {

  int rectX=width/4;
  int rectY=height/10;

  int rectSize=30;
  angle=angle+0.1;
  
  rotX = rectX*cos(angle)-rectY*sin(angle);
  rotY = rectX*cos(angle)+rectY*sin(angle);
  
  
  square(rotX, rotY, rectSize);
}

此外，如果要从中心绘制，则可以在渲染之前将宽度/高度的一半添加到方形坐标（相等的要翻译成中心），如果您想绘制一个圆而不是椭圆形，请使用两个RADII的大小（命名rectx，retecty，retecty）：

float rotX, rotY;
float angle = 0;

void setup() {
  size(500, 500);

  fill(#B71143);

  rectMode(CENTER);
}

void draw() {

  int rectX=width/4;
  int rectY=height/4;

  int rectSize=30;
  angle=angle+0.1;
  
  rotX = rectX*cos(angle)-rectY*sin(angle);
  rotY = rectX*cos(angle)+rectY*sin(angle);
  
  // offset to center
  rotX += width / 2;
  rotY += height / 2;
  
  square(rotX, rotY, rectSize);
}

就我个人而言，我会有点简化代码（尽管您的作业要求可能会根据您的课程而有所不同）。

// initialise angle value
float angle = 0;

void setup() {
  size(500, 500);

  fill(#B71143);
}

void draw() {
  // circular motion radius
  int radius = width / 4;
  // define square size
  int rectSize=30;
  // increment the angle (rotating around center)
  angle=angle+0.1;
  // convert polar (angle, radius) to cartesian(x,y) coords
  float x = cos(angle) * radius;
  float y = sin(angle) * radius;
  
  // offset to center
  x += width / 2;
  y += height / 2;
  // render the square at the rotated position
  square(x, y, rectSize);
}

（如果您是沿着笛卡尔坐标的另一个极地转换公式的说明，则可以在这里查看我的较旧答案其中包括互动演示）