SP_GetAppLock为什么不立即返回控件？

Question

当我的应用程序中的两个用户运行以下过程时：

CREATE PROCEDURE [dbo].[CopyForm](@varId as uniqueidentifier)
AS
BEGIN
    DECLARE @returnLock INT
    BEGIN try
        EXEC @returnLock = Sp_getapplock
        @Resource = 'CopyFormLock',
        @LockMode = 'Exclusive',
        @LockOwner = 'Session'
 
        IF @returnLock <> 0
        BEGIN
            RAISERROR (
            'the operation is occupied by another user, wait a few minutes',
            16,1
            )
            RETURN
        END
        
        --do stuff

        EXEC @returnLock = Sp_releaseapplock
        @Resource = 'CopyFormLock',
        @LockOwner = 'Session'
    END try
    BEGIN catch
        IF @returnLock = 0
        BEGIN
            EXEC @returnLock = Sp_releaseapplock
                @Resource = 'CopyFormLock',
                @LockOwner = 'Session'
        END
    END catch
END
GO

第一个锁定该过程的用户执行该过程，然后解锁它。第二个用户等待，仅在第一个用户删除锁之后，第二用户才会出现错误：“操作由另一个用户占用，等待几分钟”。 我不明白为什么第二个用户不会立即输出错误，我必须等待第一个错误。 解释我在哪里犯了一个错误，以及如何立即显示错误？

Answer 1

您在这里有许多问题：

• sp_getapplock的结果始终小于失败中的0。如果等于1，则意味着必须等待。
• 如果您希望该过程立即纾困，如果锁定锁定，请通过@locktimeout = 0。
• 使用投掷而不是raiserror。

CREATE OR ALTER PROCEDURE [dbo].[CopyForm](@varId as uniqueidentifier)
AS

SET NOCOUNT ON;

    DECLARE @returnLock INT
    BEGIN TRY
        EXEC @returnLock = sp_getapplock
        @Resource = 'CopyFormLock',
        @LockMode = 'Exclusive',
        @LockOwner = 'Session',
        @LockTimeout = 0;
 
        IF @returnLock < 0
        BEGIN
            THROW
              50001,
              'the operation is occupied by another user, wait a few minutes',
              1;
        END;
        
        --do stuff

        EXEC @returnLock = sp_releaseapplock
        @Resource = 'CopyFormLock',
        @LockOwner = 'Session';
    END TRY
    BEGIN CATCH
        IF @returnLock = 0
        BEGIN
            EXEC @returnLock = sp_releaseapplock
                @Resource = 'CopyFormLock',
                @LockOwner = 'Session';
        END;
        THROW;
    END CATCH

go