无法在Terraform模块中使用Terraform.tfvars

Question

面对某些问题，可以在模块内使用Terraform.TFVAR。 我的文件夹结构是

module/
      main.tf
      variable.tf
      terraform.tfvars
demo.tf
provider.tf

emo.tf的代码在

module "module" {
  source = "./module" 
}

模块文件夹内，我在变量内声明了变量，并将其值放在terraform.tfvars中。

当我运行Terraform计划时，它显示出来，

   Error: Missing required argument
  on main.tf line 1, in module "module":
   1: module "module" {
The argument "<variable_name>" is required, but no definition was found.

请让我知道解决方案，谢谢。

（当我将值作为默认变量中的值放置时，它是在工作文件。）

有关更多详细信息，我将在下面添加所有文件

-Main.tf

resource "aws_glue_catalog_database" "glue_database_demo" {
  name = var.database_name  # var
  location_uri = "s3://${var.bucket_location}"  # var
}

resource "aws_glue_catalog_table" "aws_glue_catalog_table" {
  name          = var.table_name  # var
  database_name = aws_glue_catalog_database.glue_database_demo.name

  table_type = "EXTERNAL_TABLE"

  parameters = {
    EXTERNAL              = "TRUE"
    "parquet.compression" = "SNAPPY"
  }

  storage_descriptor {
    location      = "s3://${var.bucket_location}"  # var
    input_format  = "org.apache.hadoop.hive.ql.io.parquet.MapredParquetInputFormat"
    output_format = "org.apache.hadoop.hive.ql.io.parquet.MapredParquetOutputFormat"

    ser_de_info {
      name                  = "my-stream"
      serialization_library = "org.apache.hadoop.hive.ql.io.parquet.serde.ParquetHiveSerDe"
    }

    columns {
      name = "filekey"
      type = "string"
    }

    columns {
      name = "reead_dt"
      type = "string"
    }
}

partition_keys {
  name = "load_dt"
  type = "string"
}
}

variables.tf

variable "database_name" {
}
variable "bucket_location" {
}
variable "table_name" {
}

terraform.tfvars

database_name = "mydatabase"
bucket_location = "kgvjgfkjhglbg"
table_name = "mytable"

Answer 1

这不是模块的工作方式。如果您定义一个变量，则希望您在调用它时提供一个值，除非它具有按照您已经指出的默认值定义。为了使此工作起作用，调用模块时必须提供值：

module "modules" {
  source          = "./module"
  database_name   = "mydatabase"
  bucket_location = "kgvjgfkjhglbg"
  table_name      = "mytable"
}

另一个选项是在同一目录中定义变量 file，以便从中调用该模块，例如，：

# provide input for the module
variable "database_name" {
  type        = string
  description = "Glue DB name."
}

variable "bucket_location" {
  type        = string
  description = "Bucket region."
}

variable "table_name" {
  type        = string
  description = "Glue catalog table name."
}

然后，将terraform.tfvars复制到同一目录中，您从demo.tf中调用

module "glue" {
  source          = "./module"
  database_name   = var.database_name
  bucket_location = var.bucket_location
  table_name      = var.table_name
}

模块模块的逻辑名称从模块到glue，因为它更具描述性，但不是必需的。

目录的最终前景应该是：

module/
      main.tf
      variables.tf
demo.tf
provider.tf
terraform.tfvars
variables.tf

Answer 2

在您的demo.tf文件中，在“模块”模块中，您需要提供输入变量值。

例如：

module "modules" {
  source          = "./module"
  database_name   = var.database_name
  bucket_location = var.bucket_location
  table_name      = var.table_name
}