使用Archive_file作为资源

Question

当我运行Terraform脚本时，我收到了此消息：

Warning: Deprecated Resource

using archive_file as a resource is deprecated; consider using the data source instead

问题是我该怎么做？我试图阅读有关数据源的信息，但尚未清楚任何内容。

我在lambda定义中使用Archive_file来zing我的lambda源并获取目标zip哈希。

resource "archive_file" "archive_csv_validate" {
  type        = "zip"
  source_dir  = "lambda/csv-validate"
  output_path = "artifacts/csv-validate.zip"
}

resource "aws_lambda_function" "lambda_csv_validate_function" {
  function_name    = "csv-validate"
  filename         = archive_file.archive_csv_validate.output_path
  source_code_hash = archive_file.archive_csv_validate.output_base64sha256
  handler          = "main.main"
  role             = aws_iam_role.lambda_iam_role.arn
  runtime          = "python3.9"
  timeout          = 900
}

Answer 1

现在，Archive_file是数据源。
您可以这样转换您的代码：

data "archive_file" "archive_csv_validate" {
  type        = "zip"
  source_dir  = "lambda/csv-validate"
  output_path = "artifacts/csv-validate.zip"
}

resource "aws_lambda_function" "lambda_csv_validate_function" {
  function_name    = "csv-validate"
  filename         = data.archive_file.archive_csv_validate.output_path
  source_code_hash = data.archive_file.archive_csv_validate.output_base64sha256
  handler          = "main.main"
  role             = aws_iam_role.lambda_iam_role.arn
  runtime          = "python3.9"
  timeout          = 900
}