如何重写给定/何时消除“实验”警告使用

Question

所有这些，

我有以下内容：

This is perl 5, version 26, subversion 3 (v5.26.3) built for x86_64-linux-thread-multi
(with 57 registered patches, see perl -V for more detail)

Copyright 1987-2018, Larry Wall

Perl may be copied only under the terms of either the Artistic License or the
GNU General Public License, which may be found in the Perl 5 source kit.

Complete documentation for Perl, including FAQ lists, should be found on
this system using "man perl" or "perldoc perl".  If you have access to the
Internet, point your browser at http://www.perl.org/, the Perl Home Page.

当我使用的脚本为和时，> 。

Trying to Google I found this ，这说它将以不兼容的方式进行更改。

我在Rhel8上，前进。

我想修复脚本，以便其他脚本也可以利用脚本，而不再看到这些警告。

如何重写它以摆脱警告？

蒂亚！

编辑：

很抱歉没有足够明确 - 通过修复脚本，我的意思是消除有问题的呼叫/重写。

edit2：

given($pl) {
  when(0) { print "A"; }
  when(1) { print "B"; }
  when(2) { print "C"; }
  when(3) { print "D"; }
  when(4) { print "E"; }
  default { print "Illegal "; }
}

其中$ pl只是一个整数（C中的无符号简称）。

该脚本从文件中读取一些数据。 该文件包含一些十六进制值。这些值是解析的 - 提取了一些位，然后将这些位的字符串表示形式打印在屏幕上。

EDIT3：

我尝试使用以下代码：

my %table_pl = (
  0 => sub { print "A"; },
  1 => sub { print "B"; },
  2 => sub { print "C"; },
  3 => sub { print "D"; },
  4 => sub { print "E"; },
);
for $pl( 0..5 )
{
    if( exists $table_pl{$pl} )
    {
        $table_pl{$pl}->();
    }
    else
    {
        print "Illegal ";
    }
}

但是我有一个错误：

Number found where operator expected near 1
     (Missing semicolon on the previous line?)

Answer 1

我喜欢将调度表用于此类事情。从本质上讲，这是一个哈希，其中键是有效的选项，而键的值是一个子例程，在提供有效的选项时可以执行您想做的事情。这样做会消除长长的if/else语句链。

您可以将子例程内联排列在表本身中，也可以引用其他地方定义的子例程。这里的示例显示了这两个：

use warnings;
use strict;

my %table = (
    0   => sub { print "A\n"; },
    1   => sub { print "B\n"; },
    2   => sub { print "C\n"; },
    3   => sub { print "D\n"; },
    4   => \&code_reference_example,
);

for my $pl (0..5) {
    if (exists $table{$pl}) {
        # Put the option into the table and execute
        # the assigned subroutine

        $table{$pl}->();

    } else {
        print "'$pl' is not a valid option\n";
    }
}

sub code_reference_example {
    print "E\n";
}

输出：

A
B
C
D
E
'5' is not a valid option

Answer 2

given ( $pl ) {
  when ( 0 ) { print "A"; }
  when ( 1 ) { print "B"; }
  when ( 2 ) { print "C"; }
  when ( 3 ) { print "D"; }
  when ( 4 ) { print "E"; }
  default    { print "Illegal "; }
}

缩写

given ( $pl ) {
  when ( $_ ~~ 0 ) { print "A"; }
  when ( $_ ~~ 1 ) { print "B"; }
  when ( $_ ~~ 2 ) { print "C"; }
  when ( $_ ~~ 3 ) { print "D"; }
  when ( $_ ~~ 4 ) { print "E"; }
  default          { print "Illegal "; }
}

可以将其写成

for ( $pl ) {
  if    ( $_ ~~ 0 ) { print "A"; }
  elsif ( $_ ~~ 1 ) { print "B"; }
  elsif ( $_ ~~ 2 ) { print "C"; }
  elsif ( $_ ~~ 3 ) { print "D"; }
  elsif ( $_ ~~ 4 ) { print "E"; }
  else              { print "Illegal "; }
}

，但问题的全部要点是避免损坏/实验性的智能匹配功能。这将是“等效”：

for ( $pl ) {
  if ( !looks_like_number( $_ ) ) {
     print "Illegal ";
     next;
  }
  
  if    ( $_ == 0 ) { print "A"; }
  elsif ( $_ == 1 ) { print "B"; }
  elsif ( $_ == 2 ) { print "C"; }
  elsif ( $_ == 3 ) { print "D"; }
  elsif ( $_ == 4 ) { print "E"; }
  else              { print "Illegal "; }
}

它不是完全等效的。不同之处在于，最后一个对待数字2和字符串2相同。智能匹配对他们的对待的事实是它是不可接受的设计的全部原因，因此这是可取的。

最后，在这里，调度表可以更好地工作。通常使用哈希，但是可以将数组用于给定的示例。

use Scalar::Util qw( looks_like_number );

sub is_nonneg_int {
   my $x = shift;
   return looks_like_number( $x ) && int( $x ) == $x && $x >= 0;
}

my @dispatch = (
  sub { print "A"; },
  sub { print "B"; },
  sub { print "C"; },
  sub { print "D"; },
  sub { print "E"; },
);

my $handler = is_nonneg_int( $pl ) ? $dispatch[ $pl ] : undef;
if ( $handler ) {
   $handler->();
} else {
   print "Illegal ";
}

调度表的优点是完成单个查找而不是多个比较。