背景工作者。停止线程执行

Question

下午好！ 您能告诉我如何停止执行线程吗？以下代码无效：

  Private Sub Stop_Click(sender As Object, e As EventArgs) Handles Stop.Click
        If BackgroundWorker1.IsBusy Then

            If BackgroundWorker1.WorkerSupportsCancellation Then
                BackgroundWorker1.CancelAsync()
            End If
        End If
    End Sub

Answer 1

该代码完全按照应有的操作来完成，即请求取消。不过，它不能只是停止工作，因为它不知道正在做什么工作。您是编写代码进行工作的人，因此您是必须编写代码以检查是否已要求取消并实际执行取消的人。我们不知道您正在做什么工作，因此我们不知道在哪里可以方便地检查是否已要求取消，如果有的话，在这种情况下可能需要清理什么。这是取消可能是什么样的基本示例：

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    'Raise the DoWork event in a worker thread.
    Me.BackgroundWorker1.RunWorkerAsync()
End Sub
 
'This method is executed in a worker thread.
Private Sub BackgroundWorker1_DoWork(ByVal sender As Object, _
                                     ByVal e As System.ComponentModel.DoWorkEventArgs) Handles BackgroundWorker1.DoWork
    Dim worker As System.ComponentModel.BackgroundWorker = DirectCast(sender, System.ComponentModel.BackgroundWorker)
 
    For i As Integer = 1 To 100
        If worker.CancellationPending Then
            'The user has cancelled the background operation.
            e.Cancel = True
            Exit For
        End If
 
        'Raise the ProgressChanged event in the UI thread.
        worker.ReportProgress(i, i & " iterations complete")
 
        'Perform some time-consuming operation here.
        Threading.Thread.Sleep(250)
    Next i
End Sub
 
'This method is executed in the UI thread.
Private Sub BackgroundWorker1_ProgressChanged(ByVal sender As Object, _
                                              ByVal e As System.ComponentModel.ProgressChangedEventArgs) Handles BackgroundWorker1.ProgressChanged
    Me.ProgressBar1.Value = e.ProgressPercentage
    Me.Label1.Text = TryCast(e.UserState, String)
End Sub
 
'This method is executed in the UI thread.
Private Sub BackgroundWorker1_RunWorkerCompleted(ByVal sender As Object, _
                                                 ByVal e As System.ComponentModel.RunWorkerCompletedEventArgs) Handles BackgroundWorker1.RunWorkerCompleted
    If e.Cancelled Then
        'The background operation was cancelled.
        Me.Label1.Text = "Operation cancelled"
    Else
        'The background operation completed normally.
        Me.Label1.Text = "Operation complete"
    End If
End Sub
 
Private Sub Button1_Click(ByVal sender As Object, _
                          ByVal e As EventArgs) Handles Button1.Click
    'Only cancel the background opertion if there is a background operation in progress.
    If Me.BackgroundWorker1.IsBusy Then
        Me.BackgroundWorker1.CancelAsync()
    End If
End Sub