如何在每个栏中使用值标签的GNUPLOT中绘制划船堆的直方图

Question

我想绘制划船的直方图。以下是我到目前为止所拥有的：

我使用了以下代码：

reset
set bmargin 10
set lmargin 20
set rmargin 16
set tmargin 7
show margin  

set title "" font "Verdana,27"
show title
set grid

set xlabel offset 0,-5 font "Verdana,25"
set xlabel "Number of Cores"
show xlabel
set xtics font "Verdana,18"

set ylabel offset -4,0 font "Verdana,25"
set ylabel "Time (%)"
show ylabel
set yrange [0:130]
set ytics font "Verdana,18"  
set ytics (0, 10, 20, 30, 40, 50, 60, 70, 80, 90, 100)

set style data histogram
set style histogram rowstacked title offset 0,3
set style fill solid border lt -1
set boxwidth 0.9

set key right
set key font "Verdana,17"
set key autotitle columnheader horizontal


plot newhistogram '{/=22 1-Core}', \
        for [i=2:5] 'base_vs_FHA_speedup_1core.dat' using i:xtic(1), \
     newhistogram '{/=22 2-Cores}' lt 1, \
        for [i=2:5] 'base_vs_FHA_speedup_2core.dat' using i:xtic(1) notitle, \
     newhistogram '{/=22 4-Cores}' lt 1, \
        for [i=2:5] 'base_vs_FHA_speedup_4core.dat' using i:xtic(1) notitle, \
     newhistogram '{/=22 8-Cores}' lt 1, \
        for [i=2:5] 'base_vs_FHA_speedup_8core.dat' using i:xtic(1) notitle

我有4个不同的数据文件，带有示例数据 这种

配置Col1 col2 col3 col4 col4 col5

base_vs_fha_1core.dat

Base        5       50      40.5    4.5             
FHA         5       16      38      5       1.54x

Base        9.3     47      37.3    6.3             
FHA         9.3     15      34.3    6.3     1.54x

base_vs_vs_fha_2core.dat

Base        18      41      33.9    7.06                
FHA         16.6    13.07   30.7    7.4     1.47x

base_vs_fha_4core.dat

Base        27.7    34.3    28.3    9.6             
FHA         28.3    11.45   25.3    9.6     1.34x

喜欢 在直方图中的每个栏中都标记为相应的值和每对第二直方图顶部顶部的最后一列的值。我该如何实现？

我可以合并所有4个文件并实现相同的目标吗？

Answer 1

您可以合并一个文件中的所有4个文件。我建议使用两条空行的分离，因为这样，您可以通过index轻松地解决（sub）Datablocks，请检查help Index。

对于标签，您可以制作双循环，一个用于（子）数据锁，一个用于列。您必须总结列（检查help sum）才能计算标签的y位（即直方图元素的中心）。标签的X位置对于第一个数据集很特别（因为只有列列），因此可以考虑（i*3+$ 0-（i == 0））， IE i == 0如果我等于0，则返回1，否则将返回1。

您可能想在终端设置大型字体大小，而不是多次设置它，例如：设置术语pngcairo字体“，17”。

在下面找到最小化的示例，作为进一步优化的起点。

脚本：

### rowstacked histogram with numbers in corresponding boxes
reset session

$Data <<EOD
# base_vs_FHA_1core.dat
col1 col2 col3 col4 col5
Base 5 50 40.5 4.5
FHA  5 16 38 5 1.54x


# base_vs_FHA_2core.dat
Base 9.3 47 37.3 6.3
FHA  9.3 15 34.3 6.3 1.54x


# base_vs_FHA_4core.dat
Base 18   41    33.9 7.06
FHA  16.6 13.07 30.7 7.4  1.47x


# base_vs_FHA_8core.dat
Base 27.7 34.3  28.3 9.6
FHA  28.3 11.45 25.3 9.6 1.34x
EOD

set xlabel "Number of Cores"
set ylabel "Time (%)"
set yrange [0:130]
set ytics 0, 10, 100
set grid

set style data histogram
set style histogram rowstacked title
set style fill solid 0.5 border lt -1
set boxwidth 0.9
set key top left noautotitle horizontal

N = 5   # number of last data column

plot newhistogram '1-Core' at 0, \
        for [i=2:N] $Data index 0 u i:xtic(1) ti columnheader, \
     newhistogram '2-Cores' lt 1 at 3, \
        for [i=2:N] '' index 1 u i:xtic(1), \
     newhistogram '4-Cores' lt 1 at 6, \
        for [i=2:N] '' index 2 u i:xtic(1), \
     newhistogram '8-Cores' lt 1 at 9, \
        for [i=2:N] '' index 3 u i:xtic(1), \
    for [i=0:3] for [j=2:N] '' index i u (i*3+$0-(i==0)): \
        ((sum [k=2:j] column(k))-column(j)*0.5):j w labels
### end of script

结果：