问题调用azurerm_api_management _api_operation与uri参数

Question

我正在尝试导入API操作（使用Swagger JSON规格）。但是，它抱怨我的URI参数。我有点不知所措。

这是我的Terraform片段，带有Swagger/Open API规格：

resource "azurerm_api_management_api" "sample_api_v2" {
  name                = "sample-api-v2"
  resource_group_name = data.azurerm_resource_group.rg_name
  api_management_name = module.abc01.name
  revision            = "1"
  display_name        = "Sample Data API v2"
  path                = "Sample-data/v2"
  protocols           = ["https"]
  version             = "v2"
  version_set_id      = azurerm_api_management_api_version_set.sample-api-version-set.id
  import {
    content_format = "openapi+json"
    content_value  = <<JSON
    {
    "openapi": "3.0.1",
    "info": {
        "title": "Sample API v2",
        "description": "Sample Data API v2",
        "contact": {
        "name": "John Smith",
        "email": "[email protected]"
        },
        "version": "v2"
    },
    "servers": [
        {
        "url": "https://my-api.example.com/sample-api/v2"
        }
    ],
    "paths": {
        "/businesses/{abn}": {
        "get": {
            "summary": "Get Businesses",
            "description": "Retrieve the abn information of the business with the matching abn number",
            "operationId": "get-business-by-abn",
            "parameters": [
            {
                "name": "abn",
                "in": "path",
                "required": true,
                "schema": {
                "type": "number"
                }
            }
            ],
            "responses": {
            "200": {
                "description": "ABN Found"
            }
            }
        }
        }
    },
    "components": {
        "securitySchemes": {
        "apiKeyQuery": {
            "type": "apiKey",
            "name": "subscription-key",
            "in": "query"
        }
        }
    },
    "security": [
        {
        "apiKeyQuery": []
        }
    ]
    }
    JSON
  }
}

azurerm_api_management_api_operation block定义为：

resource "azurerm_api_management_api_operation" "get_business_by_abn_v2" {
  operation_id        = "get-business-by-abn"
  api_name            = azurerm_api_management_api.sample_api_v2.name
  api_management_name = module.abc01.name
  resource_group_name = data.azurerm_resource_group.rg_name
  display_name        = "Lookup business by ABN"
  method              = "GET"
  url_template        = "/businesses/{abn}"
  description         = "Lookup a business by ABN Number"
  response {
    status_code = 200
  }
}

我遇到的错误是：我已经

: apimanagement.APIOperationClient#CreateOrUpdate: Failure responding to request: StatusCode=400 -- Original Error: autorest/azure: Service returned an error. Status=400 Code="ValidationError" Message="One or more fields contain incorrect values:" Details=[{"code":"ValidationError","message":"All template parameters used in the UriTemplate must be defined in the Operation, and vice-versa.","target":"templateParameters"}]

完成了以下操作：我已经完成了以下内容：

1. 验证了规格
2. 我已经在Swagger在线编辑器 明确定义了参数块以匹配路径：

{
   "name": "abn",
   "in": "path",
   "required": true,
   "schema": {
   "type": "number"
   }
}

我发现这仅在URI参数中发生。对于我带有查询参数的其他API，此问题不会发生。

谁能建议可能出了什么问题？谢谢。

Answer 1

它以URI参数显示您也必须在Terraform中指定：

请参阅下面的template_parameter块：

resource "azurerm_api_management_api_operation" "get_business_by_abn_v2" {
  operation_id        = "get-business-by-abn"
  api_name            = azurerm_api_management_api.sample_api_v2.name
  api_management_name = module.abc01.name
  resource_group_name = data.azurerm_resource_group.rg_name
  display_name        = "Lookup business by ABN"
  method              = "GET"
  url_template        = "/businesses/{abn}"
  description         = "Lookup a business by ABN Number"
  
  template_parameter {
    name    = "abn"
    type    = "number"
    required = true
  }
  
  response {
    status_code = 200
  }
}

在我的试验中＆amp;错误，它不在乎是否指定查询参数。但是，必须在Open API规范和Terraform资源中通过Template_Parameter部分指定URI参数。