在WHERE子句/语句中使用indexw函数

Question

我试图了解以下代码的行为。对我来说似乎是错误的，但我很感谢别人看看我只是生气或其他事情。

data testdata;
  length var1 var2 $ 10;
  var1 = "house";  var2 = "";       output;
  var1 = "house";  var2 = "car";    output;
  var1 = "house";  var2 = "house";  output;
run;

proc sql;

  * Select all three obs- ok;
  create table try1 as select * from testdata where indexw("house", var1);

  * Selects one obs - ok;
  create table try2 as select * from testdata where indexw("house", var2);

  * Selects one obs - ok;
  create table try3 as select * from testdata where indexw("car", var2);

  * Selects all three obs - why?;
  create table try4 as select * from testdata where indexw("house", var1) and indexw("house", var2);

  * Selects one obs - ok;
  create table try5 as select * from testdata where indexw("house", var1) and indexw("car", var2);

  * Explicit comparison to zero - selects one obs - ok;
  create table try6 as select * from testdata where indexw("house", var1) and (indexw("house", var2) ne 0);

  * Compare to VAR2 first - selects one obs - ok;
  create table try7 as select * from testdata where indexw("house", var2) and indexw("house", var1);

quit;

当我运行此代码时，Try1具有三个观察结果，Try2具有一个-var1 =“ House”和var2 =“ House”的观测值。这就是我所期望的，基于这一点，我希望Try4仅包含var1和var2都是“房屋”的单个观察结果。而是Try4从输入中选择所有三个观察结果。

更奇怪的是，Try6使用明确的比较零，并且只能按预期选择一个观察值，而Try7也可以逆转比较的顺序。

如果我使用某个语句，则在数据步骤中发生了类似的事情，但是如果我使用if语句：

114  data t;
115    set testdata;
116    where indexw("house", var1) and indexw("house", var2);
117  run;

NOTE: There were 3 observations read from the data set WORK.TESTDATA.
      WHERE not (not INDEXW('house', var1));
NOTE: The data set WORK.T has 3 observations and 2 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds


118  data t;
119    set testdata;
120    if indexw("house", var1) and indexw("house", var2);
121  run;

NOTE: There were 3 observations read from the data set WORK.TESTDATA.
NOTE: The data set WORK.T has 1 observations and 2 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.00 seconds

请注意，第一个数据步骤输出所有三个观察结果，而第二个数据仅输出一个。

第一步的日志揭示了一个线索 - 看起来SAS以改变其含义的方式重新解释了Where子句。

这是怎么回事？

在Windows 10上以64位SAS 9.4（TS1M7）运行。

Answer 1

该错误至少在SAS中至少可以追溯到9.4m5。直接联系SAS，以获取有关此错误的详细信息。您可以通过以下方式提出一张票： http://support.sas.com

我记得它与使用有关相同的功能（可能还要求两个用法都使用相同的第一个参数？），并且作为您的示例显示将功能结果视为布尔值。

两种表达式中的相似性使优化逻辑混淆。添加您展示的工作以避免错误的工作的显式比较操作员的工作。

 where 0<indexw("house", var1) and 0<indexw("house", var2);