主动选择反应参数不显示所需的默认分支

Question

我想使用Jenkins的主动选择反应性参数使用Groovy脚本来显示存储库中的所有分支。

我有以下代码示例以获取存储库的所有分支，并且由于有数百个分支，我希望默认值为主分支。

即使我专门插入了DefaultBranch变量，它也将第一个项目显示为默认值，而不是我编写的分支。

代码：

import com.cloudbees.plugins.credentials.CredentialsProvider;
import com.cloudbees.plugins.credentials.common.StandardUsernamePasswordCredentials;
import jenkins.model.Jenkins

def git_url ="url"

def getAllBranches(url, credentialID, activeChoice = false, defaultBranch = 'master') {
  def jenkinsCredentials = CredentialsProvider.lookupCredentials(
          com.cloudbees.jenkins.plugins.sshcredentials.impl.BasicSSHUserPrivateKey,
          Jenkins.instance
  );
  def key = jenkinsCredentials.findResult { it.id == credentialID ? it.privateKey : null }

  if( !key ) {
    return 'Error: credentials not found'
  }

  Process process = ['ssh-agent','bash','-c', "echo '" + key + "' | ssh-add - 2> /dev/null && git ls-remote -t -h " + url].execute()
  def out = new StringBuilder()
  def err = new StringBuilder()
  process.consumeProcessOutput( out, err )
  process.waitFor()
  if( err.size() > 0 ) return err
  if( out.size() > 0 ) {
      def branches = out.readLines().collect { it.split()[1].replaceAll('refs/heads/', '') }
      if( activeChoice ) {
        def defaultBranchIndex = branches.indexOf(defaultBranch)
        if( defaultBranchIndex >= 0 ) branches.set(defaultBranchIndex, defaultBranch + ':selected')
      }
      return branches
  }
}

return getAllBranches(git_url, "efa7bed9-56a0-42ac-8fa3-a68fe7700801")

Answer 1

您已经将activeChoice的默认值设置为false在getAllBranches方法中，并且在调用它时未设置，因此如果 - 添加的分支：从未输入。

Answer 2

我将ActiveChoice方法的价值从false更改为true，它解决了我的问题：

import com.cloudbees.plugins.credentials.CredentialsProvider;
import com.cloudbees.plugins.credentials.common.StandardUsernamePasswordCredentials;
import jenkins.model.Jenkins

def git_url ="url"

def getAllBranches(url, credentialID, activeChoice = true, defaultBranch = 'master') {
  def jenkinsCredentials = CredentialsProvider.lookupCredentials(
          com.cloudbees.jenkins.plugins.sshcredentials.impl.BasicSSHUserPrivateKey,
          Jenkins.instance
  );
  def key = jenkinsCredentials.findResult { it.id == credentialID ? it.privateKey : null }

  if( !key ) {
    return 'Error: credentials not found'
  }

  Process process = ['ssh-agent','bash','-c', "echo '" + key + "' | ssh-add - 2> /dev/null && git ls-remote -t -h " + url].execute()
  def out = new StringBuilder()
  def err = new StringBuilder()
  process.consumeProcessOutput( out, err )
  process.waitFor()
  if( err.size() > 0 ) return err
  if( out.size() > 0 ) {
      def branches = out.readLines().collect { it.split()[1].replaceAll('refs/heads/', '') }
      if( activeChoice ) {
        def defaultBranchIndex = branches.indexOf(defaultBranch)
        if( defaultBranchIndex >= 0 ) branches.set(defaultBranchIndex, defaultBranch + ':selected')
      }
      return branches
  }
}

return getAllBranches(git_url, "efa7bed9-56a0-42ac-8fa3-a68fe7700801")