输出列表项目和LS一样

Question

我正在尝试输出类似于LS输出的东西。这样的LS命令输出：

file1.txt   file3.txt    file5.txt
file2.txt   file4.txt

但是我此示例列表：

a b c d e f g h i j k l m n o p q r s t u v w x y z

显示为：

a e i m q u y
b f j n r v z
c g k o s w 
d h l p t x

在这种情况下，它提供了7列，但我最多想多达8列最大。下一个列表：

a b c d e f g h i j k l m n o p q r s t u v w

必须显示为：

a d g j m p s v
b e h k n q t w
c f i l o r u

和“ ABCDEFG H”，必须按以下显示，因为它已经是1行中的8列，但是：

a b c d e f g h i

将显示为：

a c e g i 
b d f h

和：：：：：：

a b c d e f g h i j

a c e g i 
b d f h j

Answer 1

一种方法：

#!/usr/bin/env tclsh                                                                                                                                                                                                                             

proc columnize {lst {columns 8}} {
    set len [llength $lst]
    set nrows [expr {int(ceil($len / (0.0 + $columns)))}]
    set cols [list]
    for {set n 0} {$n < $len} {incr n $nrows} {
        lappend cols [lrange $lst $n [expr {$n + $nrows - 1}]]
    }
    for {set n 0} {$n < $nrows} {incr n} {
        set row [list]
        foreach col $cols {
            lappend row [lindex $col $n]
        }
        puts [join $row " "]
    }
}


columnize {a b c d e f g h i j k l m n o p q r s t u v w x y z}
puts ----
columnize {a b c d e f g h i j k l m n o p q r s t u v w}
puts ----
columnize {a b c d e f g h}
puts ----
columnize {a b c d e f g h i}
puts ----
columnize {a b c d e f g h i j}

columnize函数首先要通过请求的列数的简单划分列表的简单划分，然后将列表划分为该长度的块，一个一个，一个每个列，最后通过那些为每个列提取当前行元素的订阅者迭代，并将行以空格分隔列表打印出来。