PERL：仅在没有段落的数组循环（最后一次迭代循环）上处理元素时，才能进行进一步处理

Question

我如何检查是否在数组中不存在foreach循环处理的元素？

示例：

my @array = ("abc","def","ghi");
foreach my $i (@array) {
    print "I am inside array\n";
    #####'Now, I want it further to go if there are no elements after 
    #####(or it can be said if it is the last element of array. Otherwise, go to next iteration'
    print "i did this because there is no elements afterwards in array\n";
}

我可以想到做到这一点的方法，但是想知道我是否可以使用特定的关键字或函数以短暂的方式获得它。我想的一种方式：

my $index = 0;
while ($index < scalar @array) {
    ##Do my functionality here

}
if ($index == scalar @array) {
    print "Proceed\n";
}

Answer 1

有多种方法可以实现所需的结果，有些是基于数组的$索引的使用，而其他基于使用$＃$＃array-1可以用于获得的方法Array Slice，带有$ array [-1]的数组的最后一个元素。

use strict;
use warnings;
use feature 'say';

my @array = ("abc","def","ghi");

say "
  Variation #1
-------------------";
my $index = 0;

for (@array) {
    say $index < $#array 
        ? "\$array[$index] = $array[$index]" 
        : "Last one: \$array[$index] = $array[$index]";
    $index++;
}

say "
  Variation #2
-------------------";
$index = 0;

for (@array) {
    unless ( $index == $#array ) {
        say "\$array[$index] = $_";
    } else {
        say "Last one: \$array[$index] = $_";
    }
    $index++;
}

say "
  Variation #3
-------------------";
$index = 0;

for( 0..$#array-1 ) {
    say "\$array[$index] = $_";
    $index++;
}

say "Last one: \$array[$index] = $array[$index]";

say "
  Variation #4
-------------------";

for( 0..$#array-1 ) {
    say  $array[$_];
}

say 'Last one: ' . $array[-1];

say "
  Variation #5
-------------------";
my $e;

while( ($e,@array) = @array ) {
    say @array ? "element: $e" : "Last element: $e";
}

Answer 2

一种检测处理时间在最后一个元素时的一种方法

my @ary = qw(abc def ghi);

foreach my $i (0..$#ary) { 
    my $elem = $ary[$i];
    # work with $elem ...

    say "Last element, $elem" if $i == $#ary;
}

语法$＃array-name用于数组中最后一个元素的索引。

---

还请注意，每个 在数组上有用，如果有索引的用途

while (my ($i, $elem) = each @ary) { 
    # ...
    say "Last element, $elem" if $i == $#ary;
}

，请确保阅读文档要了解每个的微妙之处。

Answer 3

取决于您要处理空数组的方式：

for my $ele ( @array ) {
    say $ele;
}

say "Proceed";

或

for my $ele ( @array ) {
    say $ele;
}

if ( @array ) {
   say "Proceeding beyond $array[-1]";
}