带有多个标准的vlookup，返回的数组插入了ComboBox

Question

有没有一种方法可以使用VBA使用多个标准进行Vlookup，然后将这些返回的值插入ComboBox？对于下表，我想将“马林鱼”作为搜索条件，然后将{rbi，score，abv}插入combobox作为选项。这可能吗？

示例数据：

标识符	价值
海盗	得分
马林斯	RBI
MARLINS	得分
Marlins	ABV
Pirates	HRS

Application.WorksheetFunction.VLookup("Marlins", Worksheets("Metadata").Range("A2:B5"), 2, False)

Answer 1

填充一个Combobox

一个简单的例子

Sub PopulateComboBox()
    
    ' Reference the worksheet.
    Dim ws As Worksheet: Set ws = ThisWorkbook.Worksheets("Metadata")
    
    ' Write the values of the range to a 2D one-based array.
    Dim sData As Variant: sData = ws.Range("A2:B5").Value
    
    ' Write the unique values from column 2, where column 1 is "Marlin",
    ' to the keys of a dictionary.
    Dim dict As Object: Set dict = CreateObject("Scripting.Dictionary")
    dict.CompareMode = vbTextCompare ' case-insensitive
    Dim r As Long
    For r = 1 To UBound(sData, 1)
        If StrComp(CStr(sData(r, 1)), "Marlin", vbTextCompare) = 0 Then
           dict(sData(r, 2)) = Empty
        End If
    Next r
    
    ' Write the values from the keys of the dictionary to the combo box.
    With ws.ComboBox1 ' active-x combobox on the worksheet
        .Clear
        If dict.Count > 0 Then .List = dict.Keys
    End With
        
End Sub

Answer 2

如果您处置VEST的较新的动态阵列功能。 MS365，
您可能会从以下函数过滤（）

• （a）返回评估的 filter（）公式字符串（基于帮助函数的结果）代码> makeformula 和
• （b）检查可能的非遇到

Function filtered(data As Range, Optional ByVal criteria As String = "Marlins")
'a) Return filtered data as 1-based 2D array.
    filtered = data.Parent.Evaluate(MakeFormula(data, criteria))
'b) (Provide for possible non-findings via Error check).
    If IsError(filtered) Then filtered = Array(Empty)
End Function

帮助函数makeformula

Function MakeFormula(data, ByVal criteria As String) As String
'0. Get Column addresses.
    Dim critAddr$: critAddr = data.Columns("A").Address(0, 0)
    Dim valsAddr$: valsAddr = data.Columns("B").Address(0, 0)
'1. Return concatenated formula - e.g. "FILTER(B2:B6,A2:A6=""Marlins"")"
    MakeFormula = "FILTER(" & valsAddr & "," & critAddr & "=""" & criteria & """)"
End Function

示例示例调用

足以传递整个数据是足够的 或可选标准，例如“马林鱼”）。

范围为参数（和/
获取（重新）由过滤值分配。

Sub ExampleCall
    ' Reference the worksheet.
    Dim ws As Worksheet: Set ws = ThisWorkbook.Worksheets("Metadata")
    ' Assign the filtered data to the combo box´es .List property.
    With ws.OLEObjects("ComboBox1")
        .Object.list = filtered(ws.Range("A2:B6"))
    End With
End Sub

Answer 3

使用ActiveX Combobox，并将默认名称作为ComboBox1。

Sub test()
Dim rg As Range: Dim cell As Range: dim crit as string

    With ActiveSheet
        Set rg = .Range("A2", .Range("A" & Rows.Count).End(xlUp))
        .ComboBox1.Clear
    End With

crit = "Marlins"

    With rg
        .Replace crit, True, xlWhole, , False, , False, False
             For Each cell In .SpecialCells(xlConstants, xlLogical).Offset(0, 1)
                ActiveSheet.ComboBox1.AddItem cell.Value
             Next
        .Replace True, crit, xlWhole, , False, , False, False
    End With
    
End Sub

该代码假设您的数据与图像附件中的数据完全相同。
因此，标识符标头位于单元格A1中，其中数据从单元A2开始。
值标头位于单元B1中，其中数据从单元格B2开始。

过程：
它作为可变RG的标识符数据范围。

创建具有价值“马林鱼”的可变暴力。

然后在RG中，它替换所有包含文本“ Marlins”的行中的行，以逻辑true，获取包含“ true”偏移量的单元格（0,1），请执行循环以将每个循环的单元格值作为ComboBox1项目，将真正的价值带回“马林鱼”。

该子必须在数据表处于活动状态的情况下运行。