在Raku中，如何编写相当于Haskell的跨度函数的等效内容？

Question

---

在Raku中，如何编写Haskell的span函数的等效内容？

在haskell中，给定谓词和列表，一个人可以将列表分为两个部分：

• 元素的最长前缀
• 满足谓词列表的剩余

，例如haskell表达式………

span (< 10) [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4]

评估是

([2,2,2,5,5,7],[13,9,6,2,20,4])

如何编写raku等效的Haskell的span功能？

---

更新1

基于@chenyf的答案，我开发了以下span subroutine（稍后的更新反映否定 在span> span保持忠实所需 Haskell的span函数 ）…

sub span( &predicate, @numberList )
  {
  my &negatedPredicate = { ! &predicate($^x) } ;
  my $idx = @numberList.first(&negatedPredicate):k ;
  my @lst is Array[List] = @numberList[0..$idx-1], @numberList[$idx..*] ;
  @lst ;
  } # end sub span

sub MAIN()
  {
  my &myPredicate = { $_ <= 10 } ;
  my @myNumberList is Array[Int] = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4] ;
  my @result is Array[List] = span( &myPredicate, @myNumberList ) ;

  say '@result is ...' ;
  say @result ;
  say '@result[0] is ...' ;
  say @result[0] ;
  say @result[0].WHAT ;
  say '@result[1] is ...' ;
  say @result[1] ;
  say @result[1].WHAT ;
  } # end sub MAIN

程序输出是…

@result is ...
[(2 2 2 5 5 7) (13 9 6 2 20 4)]
@result[0] is ...
(2 2 2 5 5 7)
(List)
@result[1] is ...
(13 9 6 2 20 4)
(List)

---

更新2

利用发布到 stackoverflow 有关Raku的nil code> nil ，SubRoutine span的以下更新的草稿是…

sub span( &predicate, @numberList )
  {
  my &negatedPredicate = { ! &predicate($^x) } ;
  my $idx = @numberList.first( &negatedPredicate ):k ;
  if Nil ~~ any($idx) { $idx = @numberList.elems ; }
  my List $returnList = (@numberList[0..$idx-1], @numberList[$idx..*]) ;
  $returnList ;
  } # end sub span

sub MAIN()
  {
  say span( { $_ == 0 }, [2, 2, 5, 7, 4, 0] ) ;  #  (() (2 2 5 7 4 0))
  say span( { $_ <  6 }, (2, 2, 5, 7, 4, 0) ) ;  #  ((2 2 5) (7 4 0))
  say span( { $_ != 9 }, [2, 2, 5, 7, 4, 0] ) ;  #  ((2 2 5 7 4 0) ())
  } # end sub MAIN

---

Answer 1

我使用第一个方法和：k副词，如下：

my @num  = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4];
my $idx = @num.first(* > 10):k;

@num[0..$idx-1], @num[$idx..*];

Answer 2

对此完全天真的看法：

sub split_on(@arr, &pred) {
  my @arr1;
  my @arr2 = @arr;

  loop {
    if not &pred(@arr2.first) {
      last;
    } 

    push @arr1: @arr2.shift
  }

  (@arr1, @arr2);
}

创建一个新的@arr1，然后将数组复制到@arr2中。循环，如果谓词是 在数组中的第一个元素满足，那是最后一次。否则，将第一个元素从@arr2中移开，然后将其推到@arr1上。

测试此问题时：

my @a = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4];
my @b = split_on @a, -> $x { $x < 10 };

say @b;

输出是：

[[2 2 2 5 5 7] [13 9 6 2 20 4]]

仅出现问题...如果未满足谓词 怎么办？好吧，让我们检查一下列表是否为空或，无法满足谓词以终止循环。

sub split_on(@arr, &pred) {
  my @arr1;
  my @arr2 = @arr;

  loop {
    if !@arr2 || not &pred(@arr2.first) {
      last;
    } 

    push @arr1: @arr2.shift;
  }

  (@arr1, @arr2);
}

Answer 3

因此，我认为我会将自己的版本扔进去，因为我认为分类可能会有所帮助：

sub span( &predicate, @list ) { 
    @list
    .classify({
        state $f = True; 
        $f &&= &predicate($_); 
        $f.Int; 
    }){1,0}
    .map( {$_ // []} )
}

MAP最后是处理谓词永远不会或永远是真的。

Answer 4

在他的演讲中 105 c ++算法Raku（***）讨论一个几乎可以回答您的问题的功能。我已经对您的问题进行了一些重新分配，但是更改很小。

#| Return the index at which the list splits given a predicate.
sub partition-point(&p, @xs) {
    my \zt = @xs.&{ $_ Z .skip };
    my \mm = zt.map({ &p(.[0]) and !&p(.[1]) });
    my \nn = mm <<&&>> @xs.keys;
    return nn.first(?*)
}

#| Given a predicate p and a list xs, returns a tuple where first element is
#| longest prefix (possibly empty) of xs of elements that satisfy p and second
#| element is the remainder of the list.
sub span(&p, @xs) {
    my \idx = partition-point &p, @xs;
    idx.defined ?? (@xs[0..idx], @xs[idx^..*]) !! ([], @xs)
}

my @a = 2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4;
say span { $_ < 10 }, @a;                #=> ((2 2 2 5 5 7) (13 9 6 2 20 4))
say span { $_ < 5 }, [6, 7, 8, 1, 2, 3]; #=> ([] [6 7 8 1 2 3])

Answer 5

Raku的6.e版将发挥新的“ Snip”功能：

use v6.e; 
dd (^10).snip( * < 5 );
#«((0, 1, 2, 3, 4), (5, 6, 7, 8, 9)).Seq␤»