如何在Terraform云搜索资源中多次调用配置块

Question

嗨，我正在尝试在云搜索index_field配置块中添加一个动态块，但是没有使用大量错误

        resource "aws_cloudsearch_domain" "this" {
  name = "${var.name}"

  scaling_parameters {
    desired_instance_type = "${var.instance_type}"
  }

  dynamic "index_field" {
    for_each = var.index_field

    content {
      name            = index_field.value["name"]
      type            = index_field.value["type"]
      search          = index_field.value["search"]
      return          = index_field.value["return"]
      sort            = index_field.value["sort"]
      highlight       = index_field.value["highlight"]
      analysis_scheme = index_field.value["analysis_scheme"]

    }  

  }

}

main.tf文件

    module "cloudsearch" {
    source = "./modules"
      name = "demo"
      instance_type = "search.2xlarge"

      index_field = {
        name = "hello"
        
        type = "text"
        index_name = "hello"
        search = "true"
        return = false
        sort = false
        highlight = true
        analysis_scheme = "_en_default_"
        }

}

var.tf文件 -

variable "name" {
    type = string
    description = "value"
}

variable "instance_type" {
  type = string
  description = "value"
}


variable "index_field" {
  description = ""
  type        = any
  default     = null
}

我要低于错误

：错误：无效索引 │ │在模块/main.tf第18行上，在资源“ aws_cloudsearch_domain”中 │18：Analysis_scheme = index_field.Value [“ Analysis__scheme”] │├│├├届─-─-─-─-─-─-─..-─..- - ─- ││index_field.value是“文本” │ │此值没有任何索引。

感谢您会很感激，谢谢

Answer 1

这里的问题是您使用的是index_field变量的键，但值是整个块。因此，您需要另一个将充当占位符密钥的密钥，因此可以通过其键的名称访问与该密钥相关的值。换句话说，当前变量的解释方式是：

key -> index_field
value -> {
        name = "hello"
        
        type = "text"
        index_name = "hello"
        search = "true"
        return = false
        sort = false
        highlight = true
        analysis_scheme = "_en_default_"
        }

为了按照您设想的方式工作，需要对将变量传递给儿童模块的方式进行一些修改：

module "cloudsearch" {
  source = "./modules"
  
  name = "demo"
  instance_type = "search.2xlarge"

  index_field = {

    first_index = { # <---- this has changed

      name = "hello"

      type            = "text"
      index_name      = "hello"
      search          = "true"
      return          = false
      sort            = false
      highlight       = true
      analysis_scheme = "_en_default_"
    }
  }

}

请注意，您可以可以从变量中获取值时也使用不同的语法：

resource "aws_cloudsearch_domain" "this" {
  name = "test"

  scaling_parameters {
    desired_instance_type = "search.2xlarge"
  }

  dynamic "index_field" {
    for_each = local.index_field

    content {
      name            = index_field.value.name
      type            = index_field.value.type
      search          = index_field.value.search
      return          = index_field.value.return
      sort            = index_field.value.sort
      highlight       = index_field.value.highlight
      analysis_scheme = index_field.value.analysis_scheme

    }

  }

}

该计划显示：

Terraform used the selected providers to generate the following execution plan. Resource actions are indicated with the following symbols:
  + create

Terraform will perform the following actions:

  # aws_cloudsearch_domain.this will be created
  + resource "aws_cloudsearch_domain" "this" {
      + arn                       = (known after apply)
      + document_service_endpoint = (known after apply)
      + domain_id                 = (known after apply)
      + id                        = (known after apply)
      + multi_az                  = (known after apply)
      + name                      = "test"
      + search_service_endpoint   = (known after apply)

      + endpoint_options {
          + enforce_https       = (known after apply)
          + tls_security_policy = (known after apply)
        }

      + index_field {
          + analysis_scheme = "_en_default_"
          + highlight       = true
          + name            = "hello"
          + return          = false
          + search          = true
          + sort            = false
          + type            = "text"
        }

      + scaling_parameters {
          + desired_instance_type     = "search.2xlarge"
          + desired_partition_count   = (known after apply)
          + desired_replication_count = (known after apply)
        }
    }