CPLEX OPL约束，计算唯一字符串

Question

OPL模型的目标是选择以最低成本的总成本来履行所有订单，我对货运上的订单限制必须交付给＆lt; = 2 ClientId。当前，最佳解决方案是将第三货运用于所有订单（因为它是最便宜的），但是有了新的约束，第三货运最多可以携带两个订单（因为每个订单均适用于不同的客户端ID）。但是如何编码该约束呢？

当前.mod文件（模型文件）

tuple TFreightTypes {
  key string Destination;
  key string VehicleType;
  int TotalWeight;
  key string Company;
  int Cost;
};

tuple TOrders {
  key int OrderNumber;
  float Weight;
  string ClientId;
  string Destination;
  string MaterialCategory;
  int CategoryPriority;
};

{TFreightTypes}    FreightTypes = ...;
{TOrders}    Orders = ...;


dvar boolean Assignment[Orders][FreightTypes];


dexpr float objective = 
  sum(o in Orders, f in FreightTypes)
     Assignment[o][f] * f.Cost;


//choose freight with total minimum cost
minimize objective;


subject to{

  //c1: all order must be fulfilled
  forall(o in Orders)
    sum(f in FreightTypes) Assignment[o][f]==1;
    
  //c2: the order on a freight must be less than 2 destination
   
}

.DAT文件（数据文件）

FreightTypes = {
    <"LONDON","Type1",20000,"SP TRANSPORTS",40000>,
    <"LONDON","Type2",20000,"SP TRANSPORTS",40000>,
    <"DURHAM","Type3",10000,"SP TRANSPORTS",30000>,

};
Orders = {
    <1,5000,"Client1","LONDON","A",0>,
    <2,1000,"Client2","DURHAM","B",1>,
    <3,2000,"Client3","LONDON","C",1>,      

};
 

Answer 1

您可以写作

//c2: the orders on a freight must be less than 2 
  forall(f in FreightTypes)
    ctMax2:
      sum(o in Orders) Assignment[o][f]<=2;

，2符合两个目的地，完整的模型看起来像

tuple TFreightTypes {
  key string Destination;
  key string VehicleType;
  int TotalWeight;
  key string Company;
  int Cost;
};

tuple TOrders {
  key int OrderNumber;
  float Weight;
  string ClientId;
  string Destination;
  string MaterialCategory;
  int CategoryPriority;
};



{TFreightTypes}    FreightTypes = ...;
{TOrders}    Orders = ...;


dvar boolean Assignment[Orders][FreightTypes];


dexpr float objective = 
  sum(o in Orders, f in FreightTypes)
     Assignment[o][f] * f.Cost;

{string} destinations={i.Destination | i in Orders};

dvar boolean Destination[FreightTypes][destinations];


//choose freight with total minimum cost
minimize objective;


subject to{
  
  forall(f in FreightTypes,d in destinations)
    Destination[f][d]==(1<=sum(o in Orders:o.Destination==d)Assignment[o][f]);

  //c1: all order must be fulfilled
  forall(o in Orders)
    sum(f in FreightTypes) Assignment[o][f]==1;
    
  //c2: the order on a freight must be less than 2 destinations
  forall(f in FreightTypes)
    ctMax2:
      sum(d in destinations) Destination[f][d]<=2;
   
}