线程中的沉睡教授问题使用C语言同步

Question

该代码由于某种原因不起作用

课程结束后，教授喜欢睡觉 - 除了学生 困扰他们回答问题。你必须写下程序 同步代表一位教授和任意的线程 学生人数。一位无关紧要的教授，请致电idleprof（）， 哪个检查学生是否在办公室外面等待 一个问题。如果没有学生在等待，就会睡觉； 否则，它标志着一个学生进入办公室并返回。一个 有一个问题要问电话到达（）的学生， 学生队列在办公室外等待信号 教授；如果没有学生在等待，那么学生就醒来了 睡觉的教授。这个想法是教授和 一个学生将从各自的职能中返回 时间”：返回后，他们讨论了一个相互兴趣的话题，然后 学生可以回到学习，教授打电话给idleprof 再次。使用Mutexes和 条件变量。您可能假设静音和状况 变量是公平的（例如，fifo）。

#include<stdio.h>
#include<stdlib.h>
#include<pthread.h>
#include <stdbool.h>

pthread_mutex_t mutex; pthread_cond_t prof,stud; int busy = 1; int std_nb = 0;

void *IdleProf() {
    //prof sleeping
    busy = 0;
    while(1){
        if(std_nb == 0) {
            printf("Professor is sleeping");
            pthread_cond_wait(&stud, &mutex);

        }
        else {
            pthread_mutex_lock(&mutex);
            busy = 1;
            printf("Professor is busy ");
            std_nb--;
            pthread_cond_signal(&prof);
            pthread_mutex_unlock(&mutex);
        }
    } }

void *ArrivingStudents() {
    pthread_mutex_lock(&mutex);
    if(busy == 0 && std_nb == 0) {
        busy = 1;
         // Waking up the Prof
        pthread_cond_signal(&stud);
        printf("Professor woke up ");
        pthread_mutex_unlock(&mutex);
    }
    else {
        std_nb++;
        //wait for students
        pthread_cond_wait(&prof,&mutex);
        pthread_mutex_unlock(&mutex);
    }


}


int main() {
    printf("Students Number?: ");
    scanf("%d",std_nb);
    pthread_t *thread;
    thread = (pthread_t*)malloc(sizeof(pthread_t)*std_nb);
    pthread_mutex_init(&mutex,NULL);
    pthread_cond_init(&prof,NULL);
    pthread_cond_init(&stud,NULL);
    for(int i=0;i<std_nb;i++) {
        pthread_create(&thread[i],NULL,IdleProf,NULL);
    }
    for(int i=0;i<std_nb;i++) {
        pthread_create(&thread[i],NULL,ArrivingStudents,NULL);
    }
    for(int i=0;i<std_nb;i++) {
        pthread_join(thread[i],NULL);
    }
    pthread_mutex_destroy(&mutex);
    pthread_cond_destroy(&prof);
    pthread_cond_destroy(&stud);
    pthread_exit(NULL); }

Answer 1

您需要考虑两个条件的条件。
教授必须睡觉，直到学生队列超过0。
当学生队列等于0时，教授必须恢复睡觉，并且教授不与学生讨论（可用）。
每个学生都必须等待队列，直到该学生处于队列并有教授。

为了使问题更有趣，教授和学生之间的每次会议都可能需要不同的时间。

以下是使用ADA编程语言编写的解决方案。

with Ada.Text_IO;               use Ada.Text_IO;
with Ada.Integer_Text_IO;       use Ada.Integer_Text_IO;
with Ada.Numerics.Float_Random; use Ada.Numerics.Float_Random;

procedure Main is
   protected student_queue is
      entry Idle_Prof;
      entry Arriving_Student (Num : Positive);
      procedure Toggle_Prof_Available;
   private
      Prof_Available : Boolean := True;
   end student_queue;

   protected body student_queue is
      entry Idle_Prof when Arriving_Student'Count > 0 is
      begin
         null;
      end Idle_Prof;

      entry Arriving_Student (Num : Positive) when Prof_Available is
      begin
         Prof_Available := False;
         Put_Line ("Professor in conference with student." & Num'Image);
      end Arriving_Student;

      procedure Toggle_Prof_Available is
      begin
         Prof_Available := True;
      end Toggle_Prof_Available;

   end student_queue;

   task type Student is
      entry See_Professor (Num : Positive);
   end Student;

   task Professor is
      entry Start;
      entry Done;
   end Professor;

   task body Student is
      Id   : Positive;
      Seed : Generator;
   begin
      Reset (Seed);
      accept See_Professor (num : Positive) do
         Id := num;
      end See_Professor;

      student_queue.Arriving_Student (Id);
      delay (Duration (Random (Seed)));
      student_queue.Toggle_Prof_Available;
   end Student;

   task body Professor is
      sleeping : Boolean := True;
   begin
      accept Start;
      loop
         select
            accept Done;
            exit;
         else
            select
               student_queue.Idle_Prof;
               sleeping := True;
            else
               if sleeping then
                  Put_Line ("Professor sleeping.");
               end if;
               sleeping := False;
            end select;
         end select;
      end loop;
   end Professor;

   type Student_list is array (Positive range <>) of Student;

   Num_students : Positive;

begin
   Put ("Enter the number of students: ");
   Get (Num_students);
   declare
      Students : array (1 .. Num_students) of Student;
   begin
      Professor.Start;
      for I in Students'Range loop
         Students (I).See_Professor (I);
         delay 0.001;
      end loop;
   end;
   Professor.Done;
end Main;

该解决方案使用ADA受保护的对象，该对象实现了Hoare监视器。 受保护的对象描述

在两个部分中实现了一个受保护的对象。受保护的对象规范既定义了受保护对象的API，也定义了受保护对象的任何私人数据成员。受保护的身体实现了定义为受保护对象的API的操作。

名为Student_queue的受保护对象实现了两个受保护的条目和一个受保护的程序。在学生_Queue的主体中，我们看到条目IDLE_PROF包含条件 arriving_student'count＆gt; 0 。由于受保护的条目可以阻止呼叫任务，因此将阻止的任务隐式放置在条目队列中。此表达式简单地评估与条目arrive_student关联的条目队列中等待的任务数。 IDLE_PROF的目的是暂停教授，直到学生进入队列为止。

条目arriving_student具有prof_available的条件，每当教授不与学生参加会议时，这是正确的。

受保护的过程toggle_prof_available提供了一个API，因此与教授会议中的学生任务可以将Student_queue的Prof_available数据成员设置为与教授一起度过随机时间后的true。

为教授宣告了一项ADA任务，并为学生宣布ADA任务类型。任务类型允许创建任意数量的学生任务实例。

ADA任务可以具有条目，允许任务直接与其他任务同步通信。教授任务有两个名为Start和完成的条目。开始入口使教授暂停，直到该计划准备在教授和任意数量的学生任务之间实施会议为止。完成的条目用于向教授任务发出终止的信号。

学生任务类型主体实现了学生的行为。学生任务主体中的接受声明会导致任务实例暂停，直到调用其se_professor条目，然后将学生编号传递给学生任务。然后，学生实例致电student_queue.Arriving_student，传递其ID号。该任务将暂停在Arriving_student入口队列中，直到该任务实例处于队列和教授的负责人。执行Arriving_student受保护条目后，学生实例延迟（类似于C睡眠）在0.0到1.0秒之间随机时间。延迟到期后，学生任务调用toggle_prof_available可使教授可用于另一个学生实例。最后，学生任务实例终止。

教授任务在上等待接受start 语句，以便等待主要任务致电教授。然后，教授任务进入一个无限的循环，该循环仅在主要任务称为教授时才终止。每次通过循环，教授任务都有条件地接受完成的条目，如果尚未调用，教授任务称为student_queue.idle_prof。如果没有立即处理该输入电话，则教授任务输出字符串“睡眠教授”。并重复其内部循环迭代。

主线程声明了一个名为Student_list的不受约束的数组类型，该类型是一系列学生任务。它还声明了一个可变num_students，该变量将容纳大于0的整数，该整数将由用户输入。

提示用户的学生人数，并将用户输入分配给NUM_STUDENTS。

定义了内部块。在该块的“声明性”部分中，创建了一个名为“学生”的实例，该实例由用户输入指定的元素数量创建。

教授开始被称为，导致教授开始与等待的学生开始睡觉和/或会议。通过学生数组来调用See_professor的循环，将学生ID设置为该数组中该元素的索引。要求延迟0.001秒，以确保操作系统调度允许按预期顺序处理学生任务。

内部块的使用具有pthreads的效果，加入了所有学生任务。在所有学生线程完成之前，内部块将无法完成。

最后，主要任务称为教授。

该程序的示例执行是：

Enter the number of students: 7
Professor sleeping.
Professor in conference with student. 1
Professor in conference with student. 2
Professor in conference with student. 3
Professor in conference with student. 4
Professor in conference with student. 5
Professor in conference with student. 6
Professor in conference with student. 7
Professor sleeping.