使用VBA插入PowerPoint标题的循环10幻灯片

Question

我在Stackoverflow中看到了此代码，该代码将标题插入一个幻灯片。

Sub add_title()

Dim shpCurrShape As Shape
Dim ppPres As Presentation

Set ppPres = ActivePresentation

With ActivePresentation.Slides.Range(Array(1, 2, 3, 4, 5))

    If Not .Shapes.HasTitle Then
        Set shpCurrShape = .Shapes.AddTitle
    Else
        Set shpCurrShape = .Shapes.Title
    End If

    With shpCurrShape
        With .TextFrame.TextRange
            '~~> Set text here
            .Text = "BLAH BLAH"
            '~~> Alignment
            .ParagraphFormat.Alignment = 1
            '~~> Working with font
            With .Font
                .Bold = msoTrue
                .Name = "Tw Cen MT"
                .Size = 24
                .Color = RGB(0, 0, 0)
            End With
        End With
    End With
End With
End Sub

我想为给定数量的幻灯片添加相同的幻灯片标题，例如前十幅幻灯片。

我知道可以通过循环进行选择，从而选择感兴趣的幻灯片范围。

另外，如何定义阵列以指示幻灯片20至30？

Answer 1

我将把幻灯片更改为其他子的决定，然后将add_title仅转到您希望更改的幻灯片。

Sub AddTitles()
    Dim i As Long
    For i = 20 to 30
        add_title i
    Next i
End Sub

Sub add_title(ByVal slideNumber As Long)
    Dim ppPres As Presentation
    Set ppPres = ActivePresentation

    With ppPres.Slides(slideNumber)
        Dim shpCurrShape As Shape
        If Not .Shapes.HasTitle Then
            Set shpCurrShape = .Shapes.AddTitle
        Else
            Set shpCurrShape = .Shapes.Title
        End If

        With shpCurrShape
            With .TextFrame.TextRange
                '~~> Set text here
                .Text = "BLAH BLAH"
                '~~> Alignment
                .ParagraphFormat.Alignment = 1
               '~~> Working with font
               With .Font
                  .Bold = msoTrue
                  .Name = "Tw Cen MT"
                  .Size = 24
                  .Color = RGB(0, 0, 0)
               End With
            End With
        End With
    End With
End Sub