如何从perl中的哈希内部的数组中打印一个元素

Question

我正在尝试打印以多维格式的API打印输出。

use strict;
use warnings;
use Data::Dumper;

my $content={
  'school_set' => 'SSET1234',
  'result' => [
    {
      'school_name' => 'school_abc',
      'display_value' => 'IL25',
      'school_link' => 'example.com',
      'status' => 'registerd',
      'status_message' => 'only arts',
      'school_id' => '58c388d40596191f',
    }
  ],
  'school_table' => 'arts_schools'
};

print "school_name is=".$content{result}[0]{school_name};
print "school_status is=".$content{result}[3]{status};

output
Global symbol "%content" requires explicit package name (did you forget to declare "my %content"?) at test8.pl line 20.
Global symbol "%content" requires explicit package name (did you forget to declare "my %content"?) at test8.pl line 21.

从结果开始，我必须打印下面的输出。

school_name = school_abc
school_status = registered

Answer 1

如果$ content是哈希参考，则需要首先将其取消。为此使用箭头操作员：

$content->{result}[0]{school_name}

只有％content的语法才有可能。

my %content = ( result => [ { school_name => 'abc' } ] );
print $content{result}[0]{school_name};

如果要打印所有结果，则必须以某种方式循环循环。例如

#!/usr/bin/perl
use warnings;
use strict;

my $content = {
    'result' => [
        {
            'school_name' => 'school_abc',
            'status' => 'registerd',
        },
        {
            'school_name' => 'school_def',
            'status' => 'pending',
        }
    ],
};

for my $school (@{ $content->{result} }) {
    print "school_name is $school->{school_name}, status is $school->{status}\n";

}

Answer 2

您的数据结构假定数组，也许将循环输出用于感兴趣的数据很有用。

显示为哈希参考的数据，将需要取消参考才能通过数组循环。

以下代码段是基于您发布的代码，并演示了如何实现所需的输出。

use strict;
use warnings;
use feature 'say';

my $dataset = {
              'school_set' => 'SSET1234',
              'result' => [
                {
                  'school_name' => 'school_abc',
                  'display_value' => 'IL25',
                  'school_link' => 'example.com',
                  'status' => 'registerd',
                  'status_message' => 'only arts',
                  'school_id' => '58c388d40596191f',
                }
              ],
              'school_table' => 'arts_schools'
            };

for my $item ( @{$dataset->{result}} ) {
    say "school_name is   = $item->{school_name}\n"
      . "school_status is = $item->{status}";
}

exit 0;

输出

school_name is   = school_abc
school_status is = registerd