在文本中间更改跨引用文本，以使用ShowFieldCodes进行小写

Question

我想将文本中间的所有交叉引用文本更改为小写，而不是句子开始时的文本。

问题是pactivedocument.Paragraphs（row）.range.text正在浏览原始文本，而不是ShowfieldCodes（或Alt+F9视图），该文本生成更长的段落和行。

Sub SetLowerCase()
Dim bBig As Boolean
Dim txt As String, row As String, pos As Integer
ActiveWindow.View.ShowFieldCodes = True
Selection.HomeKey unit:=wdStory
    With Selection.Find
        .ClearFormatting
        .Text = "^d REF"
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchWildcards = False
        Do While .Execute
            pos = Selection.Information(wdFirstCharacterColumnNumber)
            row = Selection.Information(wdFirstCharacterLineNumber)
            'The problem is that "ShowFieldCodes" generates longer paragraphs and more rows, which the next line does not take into account
            txt = ActiveDocument.Paragraphs(row).Range.Text
            If pos = 1 Then
                bBig = True
            ElseIf Mid(txt, pos - 2, 2) = ". " Then
                bBig = True
            ElseIf Mid(txt, pos - 1, 1) = "." Then
                bBig = True
            End If
            If bBig = False Then
                If Not Selection.Text Like "*Lower*" Then
                    With Selection
                        .MoveRight unit:=wdCharacter, Count:=1
                        .MoveLeft unit:=wdCharacter, Count:=1
                        .TypeText Text:="\*Lower "
                        .Fields.Update
                    End With
                End If
            Else
                bBig = False
            End If
            Selection.Collapse wdCollapseEnd
        Loop
    End With
ActiveWindow.View.ShowFieldCodes = False
End Sub

Answer 1

例如：

Sub Demo()
Application.ScreenUpdating = False
Dim Fld As Field, Rng As Range, StrRef As String
With ActiveDocument
  .ActiveWindow.View.ShowFieldCodes = False
  For Each Fld In .Range.Fields
    With Fld
      If .Type = wdFieldRef Then
        Set Rng = .Result: StrRef = Split(Trim(.Code.Text), " ")(1)
        Rng.MoveStart wdSentence, -1
        Rng.MoveEnd wdSentence, 1
        If Rng.Sentences.Count = 1 Then
          .Code.Text = "REF " & StrRef & " \* Lower \h"
        Else
          .Code.Text = "REF " & StrRef & " \* FirstCap \h"
        End If
      End If
    End With
  Next
  .Fields.Update
End With
Application.ScreenUpdating = True
End Sub

无论您采用哪种方法，您都会反对VBA对语法句子的无知。例如，请考虑以下内容：

MR。史密斯在约翰博士的杂货店花费了$ 1,234.56，购买：10.25公斤土豆； 10公斤鳄梨；和15.1公斤格林太太的宜人的澳洲坚果。

为您和我来说，这算是一句话对于VBA，它算作5 ...