使用二头肌的Azure SQL故障转移组

Question

我正在尝试使用二头肌模板实现Azure SQL故障转移组。我遇到的问题是，我无法弄清楚如何引用数据库的数据库数组作为故障转移组的数据库属性中传递的参数。在为数据库属性分配数组值时，它给了我期望字符串值的错误，而分配的是数组，这当然不正确。

resource symbolicname 'Microsoft.Sql/servers/failoverGroups@2021-11-01-preview' = {
  name: 'string'
  tags: {
    tagName1: 'tagValue1'
    tagName2: 'tagValue2'
  }
  parent: resourceSymbolicName
  properties: {
    databases: [
      'string'
    ]
    partnerServers: [
      {
        id: 'string'
      }
    ]
    readWriteEndpoint: {
      failoverPolicy: 'string'
      failoverWithDataLossGracePeriodMinutes: int
    }
  }
}

是否有人使用二头肌模板有任何有效的azure SQL故障转移组的示例，或者在解决方案上指向正确的方向？

编辑1- main.bicep： 这是我在添加Thomas的更改后尝试的代码：

param databases array
param primarySqlServerName string
param drSqlServerName string
param failovergroupName string

module primarySql '***************' = {
  Deploy primary SQL Server and database
}
module drSql '****************' = {
  Deploy secondary SQL Server
}

resource sqlServerFailoverGroup 'Microsoft.Sql/servers/failoverGroups@2020-11-01-preview' = {
  name: '${primarySqlServerName}/${failovergroupName}'
  properties: {
    databases: [for database in databases: resourceId('Microsoft.Sql/servers/databases', primarySqlServerName, database)]
    readWriteEndpoint: {
      failoverPolicy: 'Automatic'
      failoverWithDataLossGracePeriodMinutes: 60
    }
    readOnlyEndpoint: {
      failoverPolicy: 'Enabled'
    }
    partnerServers: [
      {
        id: resourceId('Microsoft.Sql/servers', drSqlServerName)
      }
    ]
  }
  dependsOn: [
    primarySql
    drSql
  ]
}

在上述部署时要低于错误：

无法处理在线资源的模板语言表达式 '1'和列“ 1289”。 '无法评估模板语言功能 'ResourceId'：所有函数参数都必须是字符串文字。请 请参阅aka.ms/arm-template-expressions/#resourceid有关使用详细信息。

Answer 1

数据库属性是字符串。 Partnerservers属性是对象的数组。

两者都期望数据库的资源ID和合作伙伴服务器。

这是使用故障转移组SQL.BICEP的部署2个SQL服务器和数据库的简单示例

：

param location string = resourceGroup().location
param sqlServerName string
param sqlServerPrincipalType string
param sqlServerAadAdminName string
param sqlServerAadAdminId string
param databaseNames array

// Create the Server
resource sqlServer 'Microsoft.Sql/servers@2020-11-01-preview' = {
  name: sqlServerName
  location: location
  tags: {}
  properties: {
    administrators: {
      administratorType: 'ActiveDirectory'
      principalType: sqlServerPrincipalType
      login: sqlServerAadAdminName
      sid: sqlServerAadAdminId
      azureADOnlyAuthentication: true
    }
  }
}

// We create the database only in the primary region
resource database 'Microsoft.Sql/servers/databases@2020-08-01-preview' = [for databaseName in databaseNames: if (!empty(databaseNames)) {
  name: empty(databaseNames) ? 'placeholder' : databaseName
  parent: sqlServer
  location: location
  sku: {
    name: 'S0'
    tier: 'Standard'
  }
  properties: {
    sourceDatabaseId: sqlServer.id
  }
}]

以及main.bicep文件：

param failoverGroupName string
param primarySqlServerName string
param primaryLocation string
param secondarySqlServerName string
param secondaryLocation string
param sqlServerPrincipalType string
param sqlServerAadAdminName string
param sqlServerAadAdminId string

param databaseNames array

module primarySql 'sql.bicep' = {
  name: 'primarySql'
  params: {
    location: primaryLocation
    sqlServerName: primarySqlServerName
    sqlServerPrincipalType: sqlServerPrincipalType
    sqlServerAadAdminName: sqlServerAadAdminName
    sqlServerAadAdminId: sqlServerAadAdminId
    databaseNames: databaseNames
  }
}

module secondarySql 'sql.bicep' = {
  name: 'secondarySql'
  params: {
    location: secondaryLocation
    sqlServerName: secondarySqlServerName
    sqlServerPrincipalType: sqlServerPrincipalType
    sqlServerAadAdminName: sqlServerAadAdminName
    sqlServerAadAdminId: sqlServerAadAdminId
    databaseNames: []
  }
}

resource sqlServerFailoverGroup 'Microsoft.Sql/servers/failoverGroups@2020-11-01-preview' = {
  name: '${primarySqlServerName}/${failoverGroupName}'
  dependsOn: [ primarySql, secondarySql ]
  properties: {
    databases: [for dataBaseName in databaseNames: resourceId('Microsoft.Sql/servers/databases', primarySqlServerName, dataBaseName)]
    readWriteEndpoint: {
      failoverPolicy: 'Automatic'
      failoverWithDataLossGracePeriodMinutes: 60
    }
    readOnlyEndpoint: {
      failoverPolicy: 'Enabled'
    }
    partnerServers: [
      {
        id: resourceId(resourceGroup().name, 'Microsoft.Sql/servers', secondarySqlServerName)
      }
    ]
  }
}