令人沮丧的Arduino问题 - 循环和案例

Question

我正在使用Arduino IDE来编程ESP32，我遇到了一个令人沮丧的问题。我正在使用Neopixel环（Adafruit Clone）。

我使用了Adafruit Neopixel演示片段，它们工作正常。现在我试图将其分开。

我想做的是聆听串行端口，然后根据结果更改Neopixel环的模式。请参阅下面的代码 - 请原谅……我一直在忙着鸟类的复制和粘贴:)

#include <Adafruit_NeoPixel.h>
#define LED_PIN    4
#define LED_COUNT 16
String inputString = "";
String controlstring = "";
int ledrange = 0;
bool stringComplete = false;

Adafruit_NeoPixel strip(LED_COUNT, LED_PIN, NEO_GRB + NEO_KHZ800);

void setup() {
  Serial.begin(115200);
  strip.begin();
  strip.setBrightness(20);
  strip.show(); // Initialize all pixels to 'off'
 // rainbow();
}

void loop() {
  switch (ledrange){
    case 0:
      Serial.println("firing case 0");
      rainbow();
      break;
    case 1:
      Serial.println("firing case 1");
      colorWipe(strip.Color(  0,   0, 255), 50); // Blue
      break; 
  }
}

void colorWipe(uint32_t color, int wait) {
  for(int i=0; i<strip.numPixels(); i++) { // For each pixel in strip...
    strip.setPixelColor(i, color);         //  Set pixel's color (in RAM)
    strip.show();                          //  Update strip to match
    delay(wait);                           //  Pause for a moment
  }
}

// Rainbow cycle along whole strip. Pass delay time (in ms) between frames.
void rainbow() {
  // Hue of first pixel runs 5 complete loops through the color wheel.
  // Color wheel has a range of 65536 but it's OK if we roll over, so
  // just count from 0 to 5*65536. Adding 256 to firstPixelHue each time
  // means we'll make 5*65536/256 = 1280 passes through this loop:
  for(long firstPixelHue = 0; firstPixelHue < 5*65536; firstPixelHue += 256) {
    // strip.rainbow() can take a single argument (first pixel hue) or
    // optionally a few extras: number of rainbow repetitions (default 1),
    // saturation and value (brightness) (both 0-255, similar to the
    // ColorHSV() function, default 255), and a true/false flag for whether
    // to apply gamma correction to provide 'truer' colors (default true).
    strip.rainbow(firstPixelHue);
    // Above line is equivalent to:
    // strip.rainbow(firstPixelHue, 1, 255, 255, true);
    strip.show(); // Update strip with new contents
    delay(10);  // Pause for a moment
  }
}

uint32_t Wheel(byte WheelPos) {
  WheelPos = 255 - WheelPos;
  if(WheelPos < 85) {
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  }
  if(WheelPos < 170) {
    WheelPos -= 85;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
  WheelPos -= 170;
  return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
}
 
void serialEvent() {
  inputString = "";
  ledrange = 0;
  while (Serial.available()) {
       char inChar = (char)Serial.read();
       inputString += inChar;
    
        if (inChar == '\n') {
     stringComplete = true;
      controlstring = inputString;
     
      ledrange = inputString.toInt();
      Serial.println(ledrange);
    }
   }
}

确实有点工作。...我说，因为它根本不是很好。切换非常慢，主要是在运行彩虹动画时。有时它也会错过一个开关。...我相信这可能是因为动画在循环，那里有一个延迟。

我对Arduino不太熟悉...设置和循环对我来说是新的。理想情况下，我想要的是一个活动处理程序，可以听取串行端口的收听，但看来我必须不断进行投票吗？这是真的吗？即使是这个Serialevent（），在主循环之后的每一次都可以运行。

如果我使用Micropython，则以与Visual Studio中的编程.NET应用更相似的方式进行此项工作 - 我的舒适区域...相对而言。

谢谢

安德鲁

Answer 1

遵循我的评论 - 这是您可以采取的措施来改善代码时机的示例。

我正在使用类将每个模式所需的任何变量分组在一起。

您甚至可以从doloop（）作为虚拟函数中从普通类中得出这些，以使loop（）代码更简单，但是我尝试不更改您的原始原始功能代码太多。

颜色扫描很快，所以我将其作为一个循环 - 但是您可以将其更改为类似于彩虹代码。

希望这将使您了解运行响应式Arduino代码时需要做的事情。

#include <Adafruit_NeoPixel.h>
#define LED_PIN    4
#define LED_COUNT 16
String inputString = "";
String controlstring = "";
int ledrange = 0;
bool stringComplete = false;

Adafruit_NeoPixel strip(LED_COUNT, LED_PIN, NEO_GRB + NEO_KHZ800);

class Rainbow {
  
  private:
    long firstPixelHue = 0 ; 
  
  public: 
    void doLoop() {
      strip.rainbow(firstPixelHue);
      strip.show();
      
      firstPixelHue += 256;
      if ( firstPixelHue >= 5*65536 ) {
        firstPixelHue = 0 ;
      }
      delay(10); 
    }
}; 

class ColorWipe {
  private:
     uint32_t color ;
     int wait ;
  
  public:
  
     ColorWipe(uint32_t color_p, int wait_p) : color(color_p), wait(wait_p) {
     }
  
  void doLoop() {
    // Clear leds before the sweep. 
    strip.fill(0);
    strip.show();
    delay(wait); 
    // This loop is quite quick, so let it run to completion each time. 
    for(int i=0; i<strip.numPixels(); i++) { // For each pixel in strip...
      strip.setPixelColor(i, color);         //  Set pixel's color (in RAM)
      strip.show();                          //  Update strip to match
      delay(wait);                           //  Pause for a moment
    }
  }
}; 

ColorWipe colorWipePattern(strip.Color(0,0,255), 50); 
Rainbow rainbowPattern ;

void setup() {
  Serial.begin(115200);
  strip.begin();
  strip.setBrightness(20);
  strip.show(); // Initialize all pixels to 'off'
 // rainbow();
}

void loop() {

  switch (ledrange){
    case 0:
      Serial.println("firing case 0");
      rainbowPattern.doLoop() ;
      break;
    case 1:
      Serial.println("firing case 1");
      colorWipePattern.doLoop() ;
      break; 
  }
}

uint32_t Wheel(byte WheelPos) {
  WheelPos = 255 - WheelPos;
  if(WheelPos < 85) {
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  }
  if(WheelPos < 170) {
    WheelPos -= 85;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
  WheelPos -= 170;
  return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
}
 
void serialEvent() {
  inputString = "";
  ledrange = 0;
  while (Serial.available()) {
       char inChar = (char)Serial.read();
       inputString += inChar;
    
        if (inChar == '\n') {
     stringComplete = true;
      controlstring = inputString;
     
      ledrange = inputString.toInt();
      Serial.println(ledrange);
    }
   }
}