从一个简单的数组中递归构建嵌套哈希

Question

得到了这个：

my @list = <one two three>;

my %hash;
my $item1 = @list.shift;
%hash{$item1} = {$item1 => 1};

my $item2 = @list.shift;
%hash{$item1} = {$item2 => 1};

my $item3 = @list.shift;
%hash{$item1}{$item2} = {$item3 => 1};

say %hash;

输出此期望的数据结构：

{one => {two => {three => 1}}}

显然，如果递归是递归的话，这会更好，所以我写了此：

sub get-hash(%parent-hash, $last-item, *@list) {
    my $item = @list.shift;
    %parent-hash{$last-item} = { $item => 1 };
    get-hash(%parent-hash{$last-item}, $item, @list) if @list;

    return %parent-hash<root>;
}

%hash = get-hash({}, 'root', @list2);

输出：

{one => {two => {three => 1}}}

虽然有效，但它感觉很不高，尤其是必须传递root参数到潜艇，然后将其删除。有什么建议吗？

Answer 1

在即将推出的Raku版本中，有一种整洁的方法：

use v6.e.PREVIEW;
my @list = <one two three>;
my %hash;
%hash{||@list} = 1;
say %hash;

||表示您想将列表使用为多维 hash键。

如果您想在当前发布的语言版本中坚持使用内容，则仍然可以直接致电操作员，因为只有语法糖丢失了：

my @list = <one two three>;
my %hash;
postcircumfix:<{; }>(%hash, @list) = 1;
say %hash

两种情况下的输出都是您想要的：

{one => {two => {three => 1}}}

Answer 2

好的，玩参数的顺序有助于简化事情：

sub get-hash(@list, %parent-hash = {}, $last-item = 'root') {
    my $item = @list.shift;
    %parent-hash{$last-item} = { $item => 1 };
    get-hash(@list, %parent-hash{$last-item}, $item) if @list;

    return %parent-hash<root>;
}

my @list2 = <one two three>;
%hash = get-hash(@list2);

Answer 3

想要“键值”结构

my @list = <one two three>;
say [=>] |@list, 1

您

<one two three>
andthen |$_, 1
andthen .reduce: sub ($x,$y) is assoc<right> { %( $x => $y ) }\
andthen .say

如果

<one two three>
andthen 1, |.reverse
andthen .reduce:  { %( $^y => $^x ) }\
andthen .say