如果该行中的一个单元格有红色文本，则为单元格着色

Question

我通常会合并Excel文件输入，并检查是否发生了变化，人们以红色的单元格中突出显示。这意味着我必须从视觉上滚动整个Excel文件才能搜索这些红色单元格，以便丢失它们。 如果行中的单元格中有红色文本（或不是默认黑色的文本），是否可以在Visual Basic中将格式应用于行？ 先感谢您 卡门

Answer 1

1。 在此处解决的所有文本都

在此处解决：
根据其他单元格的字体颜色更改单元格的值

2。查找带有红色的文本的单元格

您在此处找到的起点我如何在excel vba中的单元格中找到一个单词并为红色染色（只有整个单词不是整个单词使用VBA代码？
在此处完成了每个字符的检查：

3。创建用户定义的功能，

如果您创建一个用户定义的函数以搜索所需的格式，则可以过滤这些特定行。 （请参阅上面的nr1。link）
例如，它看起来像 = ifcoloredCells（a2：e2，“”，“ no Change”）

4。将更改应用于过滤的数据

过滤后的更改数据后，您可以根据您的whishes修改格式或数据。

Answer 2

尝试以下代码：

Sub SubRedRows()
    
    'Declarations.
    Dim RngData As Range
    Dim RngTarget As Range
    Dim DblStart As Double
    Dim StrAddress As String
    
    'Settings.
    Set RngData = Range("A1:J10")
    Set RngTarget = RngData(1, 1)
    
    'Setting the format to be searched.
    Application.FindFormat.Clear
    Application.FindFormat.Font.Color = vbRed
    
    'Covering the whole RngData.
    Do
        
        'Setting RngTarget as the first cell after RngTarget with the desired format.
        Set RngTarget = Cells.Find(What:="", _
                                   After:=RngTarget, _
                                   LookIn:=xlFormulas, _
                                   LookAt:=xlPart, _
                                   SearchOrder:=xlByRows, _
                                   SearchDirection:=xlNext, _
                                   MatchCase:=False, _
                                   SearchFormat:=True _
                                  )
        
        'Checking if DblStart has been already set.
        If DblStart = 0 Then
            'If RngTarget is nothing, no range with the desired format has been found so the macro is terminated
            If RngTarget Is Nothing Then Exit Sub
            'Setting DblStart.
            DblStart = RngTarget.row
        Else
            'If RngTarget's row is equal to DblStart, the loop is left.
            If RngTarget.row = DblStart Then GoTo CP_Exit_Loop
        End If
        
        'Adding the address of the row of the cell just found to StrAddress.
        StrAddress = StrAddress & "," & Intersect(RngTarget.EntireRow, RngData).Address
        
        'Setting RngTarget for the next row.
        Set RngTarget = Cells(RngTarget.row + 1, 1)
    Loop
    
CP_Exit_Loop:
    
    'Setting the format of the range found.
    Range(Right(StrAddress, Len(StrAddress) - 1)).Font.Color = vbRed
    
    'Clearing up the find format.
    Application.FindFormat.Clear
    
End Sub

您需要根据需要更改RNGDATA的设置。它即使在具有多个区域的范围内也可以工作（即使只有其中一个相交中只有一个具有红色字体的单元格，它仍然会使所有与给定行和任何区域的相交的字体红色变为红色）。