如何正确使用Bazel Transition进行多元构建

Question

我正在尝试定义一个Bazel规则，该规则将为2个不同的平台构建2个不同的CC_Binaries，只有1个不同的平台，只有1个Bazel Build Invocation。我为如何正确定义过渡并将其连接而苦苦挣扎。

我最终希望能够做类似的事情：

cc_binary(
    name = "binary_platform_a"
    ...
)

cc_binary(
    name = "binary_platform_b"
    ...
)

my_custom_multi_arch_rule(
    name = "multiarch_build",
    binary_a = ":binary_platform_a",
    binary_b = ":binary_platform_b",
    ...
)

我从Bazel文件中推论出来：[https：//bazel.build/rules/config#user-defined-transitions]我需要在<代码> defs.bzl ：

def _impl(settings, attr):
    _ignore = (settings, attr)
    return {
        "Platform A": {"//command_line_option:platform": "platform_a"},
        "Platform B": {"//command_line_option:platform": "platform_b"},
    }

multi_arch_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//command_line_option:platform"]
)

def _rule_impl(ctx):
    # How to implement this?

my_custom_multi_arch_rule = rule(
    implementation = _rule_impl,
    attrs = {
        "binary_a": attr.label(cfg = multi_arch_transition)
        "binary_b": attr.label(cfg = multi_arch_transition)
        ...
    })

最佳案例最终方案将能够发行：

bazel build //path/to/my:multiarch_build

它成功地为其各自平台构建了我的2个单独的二进制文件。

Answer 1

这是一个不同的实现，但包括所有零件，包括平台（“@Platforms // cpu：x86_64”）。

::::::::::::::
hello.c
::::::::::::::
#include <stdio.h>
int main(char *argv) { printf("Hello\n"); }

::::::::::::::
BUILD.bazel
::::::::::::::
load("@bazel_tools//tools/build_defs/pkg:pkg.bzl", "pkg_tar")
load("multi_arch.bzl", "multi_arch")

cc_binary(
    name = "a",
    srcs = ["hello.c"],
)
cc_binary(
    name = "b",
    srcs = ["hello.c"],
)

我发现的每个示例中不清楚的部分是platforms =必须指向platform（），该使用@platforms //来定义约束。正如我在这里证明的那样：（续）

multi_arch(
    name = "a.arm",
    image = ":a",
    platforms = [":arm"],
)
multi_arch(
    name = "b.x86",
    image = ":b",
    platforms = [":x86"],
)

platform(
    name = "x86",
    constraint_values = [
        "@platforms//cpu:x86_64",
        "@platforms//os:linux",
    ]
)
platform(
    name = "arm",
    constraint_values = [
        "@platforms//cpu:aarch64",
        "@platforms//os:linux",
    ]
)

pkg_tar(
    name = "tar-t",
    srcs = [
        ":a.arm",
        ":b.x86",
    ],
)
::::::::::::::
multi_arch.bzl
::::::::::::::    
def _multi_arch_transition_impl(settings, attr):
    return [
        {"//command_line_option:platforms": str(platform)}
        for platform in attr.platforms
    ]

multi_arch_transition = transition(
    implementation = _multi_arch_transition_impl,
    inputs = [],
    outputs = ["//command_line_option:platforms"],
)

def _multi_arch_impl(ctx):
    return DefaultInfo(files = depset(ctx.files.image))

multi_arch = rule(
    implementation = _multi_arch_impl,
    attrs = {
        "image": attr.label(cfg=multi_arch_transition),
        "platforms": attr.label_list(),
        "_allowlist_function_transition": attr.label(
            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
        )
    }
)

在建造焦油并解开包装后，证明它有效：

$ file /tmp/[ab]
/tmp/a: ELF 64-bit LSB executable, ARM aarch64...
/tmp/b: ELF 64-bit LSB shared object, x86-64...

警告：这是我第一次进行过渡，没有告诉我我是否犯了菜鸟的错误，但肯定适用于我想要什么！

Answer 2

使用ctx.split_attr。

def _rule_impl(ctx):
   binary_a_platform_a = ctx.split_attr.binary_a["Platform A"]
   binary_a_platform_b = ctx.split_attr.binary_b["Platform B"]
   # ...

   return [DefaultInfo(files = depset([binary_a_platform_a, binary_b_platform_b, ...]))]

https://bazel.build/rules/config#accessing-attributes-with-过渡

Answer 3

有了一些错别字和其他修复程序，我可以同时使用您和 jin's 示例。

def _impl(settings, attr):
    _ignore = (settings, attr)

    # I'm using my default platform and a custom ARM
    # platform I have as platforms A and B.
    return {
        "Platform A": {"//command_line_option:platforms": "@local_config_platform//:host"},            
        "Platform B": {"//command_line_option:platforms": "//platforms:arm64"},
    }

multi_arch_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//command_line_option:platforms"],
)

def _rule_impl(ctx):
    binary_a_platform_a = ctx.split_attr.binary_a["Platform A"]
    binary_b_platform_b = ctx.split_attr.binary_b["Platform B"]
    files = binary_a_platform_a.files.to_list() + binary_b_platform_b.files.to_list()

    return [DefaultInfo(
        files = depset(direct = files),
    )]

my_custom_multi_arch_rule = rule(
    implementation = _rule_impl,
    attrs = {
        "_allowlist_function_transition": attr.label(
            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
        ),
        "binary_a": attr.label(cfg = multi_arch_transition),
        "binary_b": attr.label(cfg = multi_arch_transition),
    },
)