GLSL试图将数据传递到几何设计着色器时

Question

我有一个顶点着色器，可以在适当的位置，纹理坐标，正态和一些制服：

#version 330 core

layout(location = 0) in vec4 position;
layout(location = 1) in vec2 texCoord;
layout(location = 2) in vec3 normal;

//MVP
uniform mat4 u_Model;
uniform mat4 u_View;
uniform mat4 u_Proj;

//Lighting
uniform mat4 u_InvTranspModel;
uniform mat4 u_LightMVP;

out DATA
{
    vec2 v_TexCoord;
    vec3 v_Normal;
    vec3 v_FragPos;
    vec4 v_LightSpacePos;
    mat4 v_Proj;
} data_out[];

void main()
{   
    gl_Position = u_Model * position;
    data_out.v_TexCoord = texCoord;
    data_out.v_Normal = mat3(u_InvTranspModel) * normal;
    data_out.v_Proj = u_Proj * u_View * u_Model;

    //Light
    data_out.v_FragPos = vec3(u_Model*position);
    data_out.v_LightSpacePos = u_LightMVP * position;
}

我经过我的几何形状着色器：

#version 330 core

layout(triangles) in;
layout(triangle_strip, max_vertices = 3) out;

in DATA
{
    vec2 v_TexCoord;
    vec3 v_Normal;
    vec3 v_FragPos;
    vec4 v_LightSpacePos;
    mat4 v_Proj;
} data_in[];

out vec2 g_TexCoord;
out vec3 g_Normal;
out vec3 g_FragPos;
out vec4 g_LightSpacePos;

void main()
{ 
    gl_Position = data_in[0].v_Proj * gl_in[0].gl_Position;
    g_Normal = data_in[0].v_Normal;
    g_FragPos = data_in[0].v_FragPos;
    g_TexCoord = data_in[0].v_TexCoord;
    g_LightSpacePos = data_in[0].v_LightSpacePos;
    EmitVertex();

    gl_Position = data_in[1].v_Proj * gl_in[1].gl_Position;
    g_Normal = data_in[1].v_Normal;
    g_FragPos = data_in[1].v_FragPos;
    g_TexCoord = data_in[1].v_TexCoord;
    g_LightSpacePos = data_in[1].v_LightSpacePos;
    EmitVertex();

    gl_Position = data_in[2].v_Proj * gl_in[2].gl_Position;
    g_Normal = data_in[2].v_Normal;
    g_FragPos = data_in[2].v_FragPos;
    g_TexCoord = data_in[2].v_TexCoord;
    g_LightSpacePos = data_in[2].v_LightSpacePos;
    EmitVertex();

    EndPrimitive();
}

但是我遇到了错误：

ERROR: 0:28: '.' : dot operator to an array only takes length()
ERROR: 0:28: 'assign' :  cannot convert from 'attribute 2-component vector of highp        float' to 'varying unknown-sized array of highp block'
ERROR: 0:29: '.' : dot operator to an array only takes length()
ERROR: 0:29: 'assign' :  cannot convert from '3-component vector of highp float' to 'varying unknown-sized array of highp block'
................ Etc

我会在传递给几何ry的顶点着色器中的每个变量中得到这些错误着色器。

该着色器以无几何着色器形式的形式起作用，并且应该设置为当前什么都不做，那么我做错了什么？

Answer 1

即使下一个阶段为a getemetry shinder a>。 vertex shader 处理一个单个顶点，因此，输出始终是单一的值那个顶点。几何着色器的输入界面是一个数组，因为几何着色器将原始（多个顶点）作为输入而不是单个顶点。在顶点着色器中删除[]：

out DATA
{
    vec2 v_TexCoord;
    vec3 v_Normal;
    vec3 v_FragPos;
    vec4 v_LightSpacePos;
    mat4 v_Proj;
} data_out;           // <--- remove []