输出中每个参考索引的Terraform

Question

我有一个模块，在该模块中，我可以使用for_each生成几个lambdas。

resource "aws_lambda_function" "profile" {
  for_each = local.lambdas

  function_name = each.value.lambda_name
  role          = var.lambda_assume_role_arn
  image_uri     = each.value.ecr_repository_uri
  package_type  = "Image"

  vpc_config {
    security_group_ids = [var.rds_security_group_id]
    subnet_ids         = var.subnet_ids
  }
}

我需要在输出中导出

output "aws_lambda_function_pre_sign_up_arn" {
  value       = aws_lambda_function.profile[9].arn
}

output "aws_lambda_function_post_confirmation_arn" {
  value       = aws_lambda_function.profile[0].arn
}

。

╷
│ Error: Invalid index
│ 
│   on ../modules/services/profile/ouptput.tf line 2, in output "aws_lambda_function_pre_sign_up_arn":
│    2:   value       = aws_lambda_function.profile[9]
│     ├────────────────
│     │ aws_lambda_function.profile is object with 10 attributes
│ 
│ The given key does not identify an element in this collection value. An object only supports looking up attributes by name, not by numeric index.
╵
╷
│ Error: Invalid index
│ 
│   on ../modules/services/profile/ouptput.tf line 7, in output "aws_lambda_function_post_confirmation_arn":
│    7:   value       = aws_lambda_function.profile[0]
│     ├────────────────
│     │ aws_lambda_function.profile is object with 10 attributes
│ 
│ The given key does not identify an element in this collection value. An object only supports looking up attributes by name, not by numeric index.
╵

这些生成的lambdas中的两个 总共有10个。

locals {
  service = "profile"
  lambdas = {
    assign_default_group = {
      lambda_name                  = "${lower(var.company)}-${local.service}-${var.environment}-assign_default_group",
      ecr_repository_name          = "${lower(var.company)}/${local.service}/${var.environment}/lambda/assign_default_group",
      ecr_repository_uri           = "xxx.dkr.ecr.${var.region}.amazonaws.com/${lower(var.company)}/${local.service}/${var.environment}/lambda/assign_default_group:latest"
      lambda_environment_variables = {
        RDS_STORAGE_URL      = var.storage_url
        COGNITO_USER_POOL_ID = jsondecode(data.aws_secretsmanager_secret_version.profile.secret_string)["cognito_user_pool_id"]
      }
    },
    create_account = {
      lambda_name                  = "${lower(var.company)}-${local.service}-${var.environment}-create_account",
      ecr_repository_name          = "${lower(var.company)}/${local.service}/${var.environment}/lambda/create_account",
      ecr_repository_uri           = "xxx.dkr.ecr.${var.region}.amazonaws.com/${lower(var.company)}/${local.service}/${var.environment}/lambda/create_account:latest"
      lambda_environment_variables = {
        RDS_STORAGE_URL = var.storage_url
      }
    },
...

Answer 1

如评论中所述，不可能使用for_each meta-argument创建的资源使用索引[1]。如果需要使用索引，则应使用计数 Meta-argument [2]。如果您决定继续使用for_each，则可以以以下方式获取所需的输出：

output "aws_lambda_function_pre_sign_up_arn" {
  value       = aws_lambda_function.profile["first_key"].arn
}

output "aws_lambda_function_post_confirmation_arn" {
  value       = aws_lambda_function.profile["last_key"].arn
}

因为我不知道哪个键是第一个键（我猜nistion_default_group）这是最后一个（为了举例来说，让我们使用create_account），以上变为：

output "aws_lambda_function_pre_sign_up_arn" {
  value       = aws_lambda_function.profile["assign_default_group"].arn
}

output "aws_lambda_function_post_confirmation_arn" {
  value       = aws_lambda_function.profile["create_account"].arn
}

但是基于输出名称，可能有一个键nasy post_confirmation和一个名为pre_sign_up的键，因此您可以将其用作钥匙值。

如果您需要获取许多lambda函数（无论是ARN还是其他）的特定属性，则可以执行以下操作：

output "lambda_arns" {
  value = {
    for k, v in aws_lambda_function.profile : k => v.arn
  }
}

这将返回键/值对的地图，其中键将再次成为键本地变量lambdas，该值将是lambda函数。

另外，您可以将value内置函数[3]与splat表达式[4]一起派生，而返回结果将为列表（在其中您可以通过索引值引用元素）：

output "lambda_arns" {
  value = values(aws_lambda_function.profile)[*].arn
}

获取值的方法可能有更多不同的方法，但取决于您想要获得的输出类型。

---

[1] https://wwww.terraform.io/language /meta-arguments/for_each＃referring to-instances

[2] https://www.terraform.io/language/meta-arguments/count#referring-to-instances

[3]语言/函数/值“ rel =” nofollow noreferrer”> https://www.terraform.io/language/functions/vunctions/values

[4] https://www.terraform.io/language/language/expressions/splat