如何从选定的短语中汇总数字？ （SAS，SQL）

Question

我想从下面的文本中总结数字：

Kwota=237 + Kwota=30.87 + Kwota=292.74 + Kwota=292.74 + Kwota=300.87

即：

kwota = 1154,22

在示例中有5个短语，但它们的数字可能会有所不同。

文字：

[Forma sprzedazy=leasing, auto: Audi A 6, Kwota=237, Cena =123],[Forma sprzedazy=leasing, auto: Volvo, Kwota=30.87, Cena =10],[Forma sprzedazy=leasing, auto: VW Golf, Kwota=292.74, Cena =134],[Forma sprzedazy=leasing, auto: VW Golf, Kwota=292.74, Cena =134],[Forma sprzedazy=leasing, auto: Porche, Kwota=300.87, Cena =152]

Answer 1

您可以使用perl正则表达式查找kwota =＆lt; number＆gt;零件，使用匹配组提取数字文本，input> input将文本转换为数字可以以总和或总变量积累。

示例：

data have;
length text $2000;
text = catx(',',
  '[Forma sprzedazy=leasing, auto: Audi A 6, Kwota=237, Cena =123]'
, '[Forma sprzedazy=leasing, auto: Volvo, Kwota=30.87, Cena =10]'
, '[Forma sprzedazy=leasing, auto: VW Golf, Kwota=292.74, Cena =134]'
, '[Forma sprzedazy=leasing, auto: VW Golf, Kwota=292.74, Cena =134]'
, '[Forma sprzedazy=leasing, auto: Porche, Kwota=300.87, Cena =152]'
);
output;
text = 'Nothing here';
output;
run;

data want;
  length kwota_total 8;

  set have;

  rxid = prxparse ('/kwota=(\d+\.?\d+)/i');

  start = 1;
  stop = length(text);

  do while (_n_);
    call prxnext (rxid, start, stop, text, position, length);
    if position < 1 then leave;

    kwota_total = sum(kwota_total, input (prxposn(rxid,1,text), best32.));
  end;
  drop rxid start stop position length;
run;

另外，如果您直接从文本文件中读取，则可以使用基于字符的列指针控制的输入语句，例如

  ... in a loop on a single line ...
    INPUT @'Kwota=' amount @;
    total = sum(total,amount);