perl脚本在目录中搜索单词

Question

我正在寻找一个perl脚本以在目录中的所有文件中grep grop for字符串。

bash命令。 代码： grep -r'word'/path/to/dir

Answer 1

这是一项相当典型的任务，而我找不到最简单，最简单的简单工具的直接答案，便捷的 path :: tiny

use warnings;
use strict;
use feature 'say';

use Data::Dump;  # dd
use Path::Tiny;  # path 

my $dir = shift // '.';

my $pattern = qr/word/;

my $ret = path($dir)->visit( 
    sub { 
        my ($entry, $state) = @_; 
        return if not -f; 
     
        for ($entry->lines) {
            if (/$pattern/) {
                print "$entry: $_";
                push @{$state->{$entry}}, $_;  
            }   
        }   
    },  
    { recurse => 1 } 
); 

dd $ret;  # print the returned complex data structure

使用lines在此处读取文件的方式只是一种方法。它可能不适合极大的文件，因为它一次读取所有行，其中一个更好地逐行阅读。

访问方法基于Iterator，它

my $iter = path($dir)->iterator({ recurse => 1 });

my $info;

while (my $e = $iter->()) { 
    next if not -f $e; 
    
    # process the file $e as needed
    #/$pattern/ and push @{$info->{$e}}, $_ and print "$e: $_" 
    #    for $e->lines 
} 

在这里也干净地完成了此任务，我们必须提供一个数据结构来累积信息，但我们获得了更大的灵活性。

- f filetest 上面使用的“普通”文件，仍然有些允许；例如，它允许进行交换文件，例如一些编辑在会话期间保留的文件（例如VIM）。这些将导致各种比赛。要使用纯粹的ASCII或UTF-8文件，请使用-t测试。

---

否则，会有用于递归遍历和搜索的库，例如 file :: file :: find :: find :: rule ）或 path :: iterator :: ulue 。

为了完整性，这是核心 file :: find file

use warnings;
use strict;
use feature 'say';    
use File::Find;

my @dirs = @ARGV ? @ARGV : '.';

my $pattern = qr/word/;

my %res;
find( sub {
        return if not -T;  # ASCII or UTF-8 only

        open my $fh, '<', $_ or do {
            warn "Error opening $File::Find::name: $!";
            return;
        };

        while (<$fh>) { 
            if (/$pattern/) { 
                chomp;
                push @{$res{$File::Find::name}}, $_
            }
        }
    }, @dirs
);

for my $k (keys %res) { 
    say "In file $k:";
    say "\t$_" for @{$res{$k}};
}