ADA中的输入口罩

Question

-- Date: 11/06/2022

with Ada.Text_IO; Use Ada.Text_Io;

procedure Masques is
  
    type XX is record
       X1 : character range 'A'..'D';
       X2 : character range 'E'..'H';
       X3 : character range 'I'..'L';
    end record;

begin

    Get_Line (XX);

end Masques;

我正在尝试编写某种输入蒙版，以控制输入。 当然，以上示例不会编译，因为get_line无法接受记录。 当然，我们可以编写一个操作以将字符放在一起以创建字符串，通过get或get_immediate。

- 但这个想法是使用语言输入来控制输入＆amp;通过例外来捕获错误。

- 几年前，对于我的回忆，我记得有人这样做了，但我无法写。 感谢您的帮助。

Answer 1

下面证明了一种可能性：

package input_masking is
   type Account_Number is private;
   function Get_Account return Account_Number;
   procedure Display (Account : Account_Number);
   Acct_Exception : Exception;
private
   subtype F1 is character range 'A' ..'D';
   subtype F2 is character range 'E' .. 'H';
   subtype F3 is character range 'I' .. 'L';
   subtype F4 is Integer range 1111 .. 9999;
   subtype F5 is character range 'S' .. 'U';
   type Account_Number is record
      Field_1 : F1;
      Field_2 : F2;
      Field_3 : F3;
      Field_4 : F4;
      Field_5 : F5;
   end record;
end input_masking;

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Exceptions; use Ada.Exceptions;

package body input_masking is

   -----------------
   -- Get_Account --
   -----------------

   function Get_Account return Account_Number is
      Result : Account_Number;
      Input : String(1..8);
   begin
      Input := Get_Line;
      begin
         Result.Field_1 := Input(1);
      exception
         when The_Error: Others =>
            Put_Line("Invalid value in Field_1");
            Put_Line(Exception_Message(The_Error));
            raise Acct_Exception;
      end;
       begin
         Result.Field_2 := Input(2);
      exception
         when The_Error: Others =>
            Put_Line("Invalid value in Field_2");
            Put_Line(Exception_Message(The_Error));
            raise Acct_Exception;
      end;
       begin
         Result.Field_3 := Input(3);
      exception
         when The_Error: Others =>
            Put_Line("Invalid value in Field_3");
            Put_Line(Exception_Message(The_Error));
            raise Acct_Exception;
      end;
       begin
         Result.Field_4 := F4'Value(Input(4..7));
      exception
         when The_Error: Others =>
            Put_Line("Invalid value in Field_4");
            Put_Line(Exception_Message(The_Error));
            raise Acct_Exception;
      end;
       begin
         Result.Field_5 := Input(8);
      exception
         when The_Error: Others =>
            Put_Line("Invalid value in Field_5");
            Put_Line(Exception_Message(The_Error));
            raise Acct_Exception;
      end;
      return result;
   end Get_Account;

   -------------
   -- Display --
   -------------

   procedure Display (Account : Account_Number) is
      Temp : string(1..3);
      Temp2 : string(1..5);
   begin
      Temp := Account.Field_1'Image;
      Put(Temp(2));
      Temp := Account.Field_2'Image;
      Put(Temp(2));
      Temp := Account.Field_3'Image;
      Put(Temp(2));
      temp2 := Account.Field_4'Image;
      Put(Temp2(2..5));
      Temp := Account.Field_5'Image;
      Put(Temp(2));
      New_Line;
   end Display;

end input_masking;


with Input_Masking; use Input_Masking;

procedure Main is
   X : Account_Number;
begin
   X := Get_Account;
   Display(X);
end Main;

Answer 2

根据您要使用XX的操作，有很多选择可以处理类似的方法。例如：

subtype XX is String (1 .. 3) with
   Dynamic_Predicate => XX (1) in 'A' .. 'D' and
                        XX (2) in 'E' .. 'H' and
                        XX (3) in 'I' .. 'L';

YY : XX;
Last : Natural;
...
Ada.Text_IO.Get_Line (Item => YY, Last => Last);

如果last＆lt; 3或正在读取的行是＆gt; 3个字符。

通常，您将需要定义自己的get_line来执行您的要求：

procedure Get_Line (Item : out XX) is
   Line : constant String := Ada.Text_IO.Get_Line;
begin -- Get_Line
   Item.X1 := Line (line'First);
   Item.X2 := Line (line'First + 1);
   Item.X3 := Line (line'First + 2);
end Get_Line;

如果line> line> line'length＆lt； 3或line的前3个字符中的任何一个都是无效的，最后丢弃了任何额外的字符。

通常，在处理可能无效的输入时，最好用get_line函数输入整个行，然后将其解析。然后，检查line'length = 3之类的东西是一个简单的事情，或使用自定义异常。