如何在Google表中与Arrayformula一起使用SUMIF

Question

从Google表格中，我们将获得NOS车辆的输入。在一段时间内，其中一些车辆可能相同。在此期间，我们可能已经注意到这辆车辆犯的交通犯罪。我们是否可以编写代码/功能来实现所述车辆侵犯的罪行的总和？

Col A：时间戳 Col B：车辆编号（从Google表格获得的数据） Col C：输入数（通过基于Col B的Countif相似的Vookup/Query〜获得） Col D：违规数量（1如果是，空单元表示否） Col E：总违规数量〜希望总计基于Col B的总数。

因此，每次Google表格提交，Google Sheet将检查该车辆在Col E中积累并自动化的犯罪总数是多少。

谢谢您的指导。

Answer 1

如果您需要在车辆上每行的违规总数相同，则是：

=ARRAYFORMULA(
  IF(
    ROW(D:D) = 1,
      "Total Violation Count",
      IFNA(VLOOKUP(
        D:D,
        QUERY(
          D:E,
          "SELECT D, COUNT(D)
           WHERE E IS NOT NULL
           GROUP BY D"
        ),
        2,
      ))
  )
)

如果您需要违规数量的运行总和：

=ARRAYFORMULA(
  IFS(
    ROW(D:D) = 1,
      "Total Violation Count",
    A:A = "",,
    True,
      IFNA(VLOOKUP(
        MATCH(D:D, UNIQUE(FILTER(D2:D, D2:D <> "")),) * 10^INT(LOG10(ROWS(D2:D)) + 1) + ROW(D:D),
        SORT(
          {
            SEQUENCE(COUNTUNIQUE(D2:D)) * 10^INT(LOG10(ROWS(D2:D)) + 1),
            IF(SEQUENCE(COUNTUNIQUE(D2:D)), 0);
            FILTER(MATCH(D2:D, UNIQUE(FILTER(D2:D, D2:D <> "")),) * 10^INT(LOG10(ROWS(D2:D)) + 1) + ROW(D2:D), E2:E <> ""),
            MMULT(
                (FILTER(D2:D, E2:E <> "") = TRANSPOSE(FILTER(D2:D, E2:E <> "")))
              * (SEQUENCE(COUNTA(E2:E)) >= SEQUENCE(1, COUNTA(E2:E))),
              SEQUENCE(COUNTA(E2:E), 1, 1,)
            )
          }
        ),
        2
      ))
  )
)

请注意，第二解决方案具有限制：n^2＆lt; 10 000 000，其中n是违规的记录数。那就是Google的表格对也应用于中间计算的单元格总数的限制。

列f：f不使用。