可以动态创建类别名吗？

Question

得到了这个课程：

class Mass-lb is Mass {
    method new(Rat:D() $value = 1.0) {
        self.bless(
            :abbr('lb'),
            :base_value(453.59237),
            :$value,
        );
    }
}

我创建了这样的别名：

class Mass-lbs is Mass-lb { }
class Mass-pound is Mass-lb { }
class Mass-pounds is Mass-lb { }
class Mass-pnds is Mass-lb { }

但是我宁愿做这样的事情：

my @lb-syn = < lbs pounds pound pnds >;
for @lb-syn {
    EVAL 'class ::("Mass-$_") is Mass-lb {}';
}

这会引发错误：

name：：（“ ass-$ $ _”）并非已知，并且可以没有用作包装名称

PHP具有用于创建别名的内置： https://www.php.net/manual/en/en/function.class-alias.php

我找不到Raku类似的东西。

Answer 1

在Rakuast中，您可以打电话给创建新类型的类。但是Rakuast分支尚未降落。

在此之前，您使用eval的方法是有效的，您只需要更简单一点：

class Mass-lb { }
BEGIN "constant Mass-$_ = Mass-lb".EVAL
  for <lbs pounds pound pnds>;
my $mlb = Mass-lbs.new;

1. 确保在begin begin begin time创建别名。
2. 无需子类，您可以使用常数进行混叠。
3. 由于常数 s是我们的默认情况下，因此它们在eval之外可见。

Answer 2

另外，您可以使用raku Physics :: unit and physics :: Mealist ...

use Physics::Unit;
use Physics::Measure :ALL;

# define a new custom Unit
Unit.new( defn => 'lbm', names => <Mass-lb Mass-lbs Mass-pound Mass-pounds Mass-pnds> );

say GetUnit('Mass-lbs').names;      #[Mass-lb Mass-lbs Mass-pound Mass-pounds Mass-pnds]

# use the Unit in a Measure 
my $mass = ♎️'42 Mass-pnds';
say $mass;                          #42Mass-lb
say $mass.^name;                    #(..Mass) ...class name

# convert to another Unit
my $kgm = $mass.in: 'kg';
say $kgm;                           #19.05087954kg

# convert back 
say $kgm.in: 'Mass-pound';          #42Mass-lb

# raku Rats mean that the back conversion is identical
say $kgm cmp $mass;                 #Same

# with % or abs Error
my $mass2 = ♎️'42 Mass-pnds ±3%';
say $mass2;                         #42Mass-lb ±1.26
say $mass2.in: 'kg';                #19.05087954kg ±0.5715263862

更多信息，请访问github 物理::单元 and Physics :: MEATH ...