MS Access VBA等效于Ctrl＆＃x2b;＆＃x27;？

Question

我有一个艰难的时间如何从我的用户表格上的上一个记录中正确复制特定的字段数据。我没有代码示例可以显示，但我的请求非常简单。

目前，在12个字段中，我有6个经常重复数据。我可以单击并按 ctrl +'（“从上一个记录中的同一字段插入值”），它执行我想要的任务。但是，它为任务增加了很多时间。我只想编写VBA代码以对那些特定字段执行该命令。

我无法获得sendkeys工作。 dlast似乎有时会提供随机数据。我觉得这应该是一个非常简单的请求，但是由于某种原因，我没有找到功能解决方案。

Answer 1

不要摆弄数组或查询 - 使用dao 的功率：

Private Sub CopyButton_Click()

    CopyRecord
    
End Sub

• 如果选择了记录，请复制此记录。
• 如果选择了新记录，请复制最后一个（上一个）记录。

Private Sub CopyRecord()
  
    Dim Source        As DAO.Recordset
    Dim Insert        As DAO.Recordset
    Dim Field         As DAO.Field
    
    ' Live recordset.
    Set Insert = Me.RecordsetClone
    ' Source recordset.
    Set Source = Insert.Clone
    
    If Me.NewRecord Then
        ' Copy the last record.
        Source.MoveLast
    Else
        ' Copy the current record.
        Source.Bookmark = Me.Bookmark
    End If
  
    Insert.AddNew
    For Each Field In Source.Fields
        With Field
            If .Attributes And dbAutoIncrField Then
                ' Skip Autonumber or GUID field.
            Else
                Select Case .Name
                    ' List names of fields to copy.
                    Case "FirstField", "AnotherField", "YetAField"  ' etc.
                        ' Copy field content.
                        Insert.Fields(.Name).Value = Source.Fields(.Name).Value
                End Select
            End If
        End With
    Next
    Insert.Update
    
    Insert.Close
    Source.Close
    
End Sub

顺便说一句，这也是一个很好的例子，说明了RecordSetClone和recordset的clone clone - 第一个是“表单的记录”，而又是第二个是独立副本。

这也意味着表单将自动更新和立即。

Answer 2

只要编辑简单表的简单表格，并且绑定的数据字段名称与控件名称匹配，则可以逃脱将

If Me.Recordset.AbsolutePosition > 0 Then
  With Me.Recordset.Clone()
    .AbsolutePosition = Me.Recordset.AbsolutePosition - 1
    
    Dim control_name As Variant
    For Each control_name In Array("field1", "field2", "field3", "field4", "field5", "field6")
      Me.Controls(control_name).Value = .Fields(control_name).Value
    Next
  End With
End If

其分配给同一表单上的单独按钮。

Answer 3

您已经有一个好主意帖子了。

您也可以说将功能放在之前的插入事件中。此事件只有在您开始输入新的recrd时就会发射，并且它变得肮脏。

因此，也许这样做：

Private Sub Form_BeforeInsert(Cancel As Integer)

   Dim rstPrevious     As DAO.Recordset
   Dim strSQL          As String
   
   strSQL = "SELECT TOP 1 * FROM tblPeople ORDER BY ID DESC"
   
   Set rstPrevious = CurrentDb.OpenRecordset(strSQL)
   
   ' auto file out some previous values
   
   If rstPrevious.RecordCount > 0 Then
   
     Me.Firstname = rstPrevious!Firstname
     Me.LastName = rstPrevious!LastName
           
  End If

End Sub

要设置控件/字段的“列表”或“数组”的一些好主意，因此您不必编写很多代码。 （如在其他帖子/答案中所建议的那样）