FILESTREAM字节未正确编写

Question

为什么使用RAD Studio 10.1中的以下代码获得错误的输出？

var
  sPalette : string;
  mystream: TfileStream;
begin
  mystream := TfileStream.Create('C:\Data\test.bmp', fmCreate);
  sPalette := #1#2#3#4#5#6;
  mystream.WriteBuffer(Pointer(sPalette)^, Length(sPalette));
  mystream.Free;
end;

获得输出：01 00 02 00 03 00

预期输出：01 02 03 04 05 06

Answer 1

在Delphi 2009+中，String是16位，UTF-16编码Unicodestring。您没有考虑到sizeof（char）是2个字节，而不是您期望的1个字节。 长度（String）以字符数量表示，而不是字节数。您的字符串长度为6个字符，但大小为12个字节。您仅将字符串的第一个字节写入文件。而且，由于您的字符串包含下面的ASCII字符＃128，因此每个其他字节都是$ 00。

使用8位ansistring，例如：

var
  sPalette : AnsiString;
  mystream: TFileStream;
begin
  mystream := TFileStream.Create('C:\Data\test.bmp', fmCreate);
  try
    sPalette := #1#2#3#4#5#6;
    mystream.WriteBuffer(Pointer(sPalette)^, Length(sPalette));
  finally
    mystream.Free;
  end;
end;

或者，使用tencoding将Unicode字符串转换为8位字节编码：

var
  sPalette : string;
  bytes: TBytes;
  mystream: TFileStream;
begin
  mystream := TFileStream.Create('C:\Data\test.bmp', fmCreate);
  try
    sPalette := #1#2#3#4#5#6;
    bytes := TEncoding.Default.GetBytes(sPalette);
    mystream.WriteBuffer(Pointer(bytes)^, Length(bytes));
  finally
    mystream.Free;
  end;
end;

或者：另外：

var
  sPalette : string;
  mystream: TStreamWriter;
begin
  mystream := TStreamWriter.Create('C:\Data\test.bmp', False, TEncoding.Default);
  try
    sPalette := #1#2#3#4#5#6;
    mystream.Write(sPalette);
  finally
    mystream.Free;
  end;
end;

不过，您真的不应该是首先使用字符串作为二进制数据。例如，使用字节数组，例如：

var
  bytes: TBytes;
  mystream: TFileStream;
begin
  mystream := TFileStream.Create('C:\Data\test.bmp', fmCreate);
  try
    SetLength(bytes, 6);
    bytes[0] := $1;
    ...
    bytes[5] := $6;
    mystream.WriteBuffer(Pointer(bytes)^, Length(bytes));
  finally
    mystream.Free;
  end;
end;

或者更好，只需使用tbitmap对象，因为您正在写入.bmp文件，例如：

var
  bmp: TBitmap;
begin
  bmp := TBitmap.Create;
  try
    ...
    bmp.SaveToFile('C:\Data\test.bmp');
  finally
    bmp.Free;
  end;
end;