在DataGridView中搜索带有输出的JSON文件的内容

Question

该表单具有文本字段和一个datagridView。不必在数据杂志中显示JSON文件的整个内容，以搜索JSON文件的内容并在DataGridView中显示搜索结果。
您需要在用户名标签上搜索。您需要在文本字段中开始键入名字或姓氏，然后在DataGridView中显示找到的结果。

如何在DataGridView中读取文本文件：

Imports System.IO
Imports Newtonsoft.Json

Public Class Form1

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim result = JsonConvert.DeserializeObject(Of List(Of Users))(File.ReadAllText("D:\Users.json"))
        DataGridView1.DataSource = result
    End Sub

      Public Class Users
        Public Property ID() As Integer
        Public Property UserName() As String
        Public Property Login() As String
        Public Property Title() As String
        Public Property Dep() As String
        Public Property Mail() As String
        Public Property Phone() As String
    End Class
End Class

我也知道如何进行文件搜索。仅出于某种原因显示结果 - 第一个元素找到：

Dim json As String = File.ReadAllText("D:\Users.json")
Dim objectList = JsonConvert.DeserializeObject(Of List(Of Users))(json)
Dim foundItem = objectList.Where(Function(underscore) underscore.UserName.Contains("Tom")).FirstOrDefault()

If foundItem IsNot Nothing Then
    MessageBox.Show(foundItem.UserName)
Else
    MsgBox("none")
End If

JSON文件本身的实际内容：

[
{
"id":"1",
"UserName":"Fred Smith",
"Login":"f.smith",
"Title":"engineer",
"Dep":"IT infrastcomcture",
"Mail":"[email protected]",
"Phone":"111",
},
{
"id":"2",
"UserName":"Ben Taylor",
"Login":"b.taylor",
"Title":"programmer",
"Dep":"IT infrastcomcture",
"Mail":"[email protected]",
"Phone":"100",
},
{
"id":"3",
"UserName":"Steve Harris",
"Login":"s.harris",
"Title":"System Administrator",
"Dep":"IT infrastcomcture",
"Mail":"[email protected]",
"Phone":"263",
},
{
"id":"4",
"UserName":"Tom Walker",
"Login":"t.walker",
"Title":"engineer",
"Dep":"IT infrastcomcture",
"Mail":"[email protected]",
"Phone":"263",
},
{
"id":"5",
"UserName":"Tom Davis",
"Login":"t.davis",
"Title":"engineer",
"Dep":"IT infrastcomcture",
"Mail":"[email protected]",
"Phone":"200",
},
{
"id":"6",
"UserName":"Ben Walker",
"Login":"b.walker",
"Title":"System Administrator",
"Dep":"IT infrastcomcture",
"Mail":"[email protected]",
"Phone":"167",
},
]

Answer 1

需要注意的几件事：

• 此处介绍的JSON代表了所有具有相同属性的对象。它可以被视为 Records 或 Rows 的数组。
• 您需要对此JSON进行挑选，在DataGridView中介绍结果，并允许用户过滤并可能对数据进行排序。

您目前可以将此JSON划分为简单收集的类对象，这很好。如果您想过滤和排序此集合，它可能会变得更加复杂，因为一个简单的 list＆lt; t＆gt; 本身不支持它。绑定清单也不是。
您应该实现 ibindinglistview 处理对象列表，并且很可能还很可能还处理基类中的接口（您的当前用户类）。
或者使用ORM / Mini-orm。

已经建立了一种已经实现所有这些功能的已经建立的（和测试）类型noreferrer“> datatable class。
如前所述，您的JSON实际上是一个表（ Records 的数组），因此将其列为数据表非常简单。只是：

Dim dt = JsonConvert.DeserializeObject(Of DataTable)(json) 

数据级类已经允许过滤，设置其属性和排序，设置其 DefaultView.Sort 属性。

尽管如此，我建议使用介体在数据词和UI之间。
该工具非常有用，因为它提供了过滤和分类数据源的常用方法，但只要数据源实际上具有这些功能。
使用BindingSource，无论数据源是什么。
它还生成了一些有用的事件，如， ， currentchanged 活动等等。
ListChanged 事件还提供了指定更改类型的参数。

使用BindingSource，以序列化回JSON，如果数据发生了变化：

[BindingSource].EndEdit()
Dim json = JsonConvert.SerializeObject([BindingSource].DataSource, Formatting.Indented)

---

在示例代码中，使用这些对象（请参阅视觉示例）：

• usersSource ：bindingsource对象
• tboxfilteruser < /code>：文本框控件，使用用户名 property
• tboxFilterTitle ：一个文本框控件，使用 title> title> title property过滤
• 数据代码> btnremovefilter ：用于删除当前过滤器的按钮控件
• dgv ：dataGridView控件

Public Class SomeForm

    Private UsersSource As New BindingSource()
    ' Current filters
    Private UserNameFilter As String = "UserName LIKE '%%'"
    Private UserTitleFilter As String = "Title LIKE '%%'"

    Protected Overrides Sub OnLoad(e As EventArgs)
        MyBase.OnLoad(e)

        Dim json = File.ReadAllText("D:\Users.json")
        Dim dt = JsonConvert.DeserializeObject(Of DataTable)(json)
        dt.AcceptChanges()
        UsersSource.DataSource = dt
        dgv.DataSource = UsersSource
    End Sub

    Private Sub tBoxFilterUser_TextChanged(sender As Object, e As EventArgs) Handles tBoxFilterUser.TextChanged
        Dim tbox = DirectCast(sender, TextBox)
        UserNameFilter = $"UserName LIKE '%{tbox.Text}%'"
        UsersSource.Filter = $"{UserNameFilter} AND {UserTitleFilter}"
    End Sub

    Private Sub tBoxFilterTitle_TextChanged(sender As Object, e As EventArgs) Handles tBoxFilterTitle.TextChanged
        Dim tbox = DirectCast(sender, TextBox)
        UserTitleFilter = $"Title LIKE '%{tbox.Text}%'"
        UsersSource.Filter = $"{UserNameFilter} AND {UserTitleFilter}"
    End Sub

    Private Sub btnRemoveFilter_Click(sender As Object, e As EventArgs) Handles btnRemoveFilter.Click
        tBoxFilterUser.Clear()
        tBoxFilterTitle.Clear()
        UsersSource.RemoveFilter()
    End Sub
End Class

---

这是其工作方式：