PINE脚本：是否有一种方法可以考虑计算平均值的一天中的特定小时？

Question

例如：我正在使用以下代码来计算过去7天的平均每日体积：

isess = session.regular
t = ticker.new(syminfo.prefix, syminfo.ticker, session=isess)
AvgVol7 = ta.sma(volume, 7)
SecAvgVol7 = request.security(t, 'D', AvgVol7[1], gaps=barmerge.gaps_off , lookahead=barmerge.lookahead_on)

但是我想做的是计算过去7天的相同平均每日体积，但仅考虑从凌晨6点到凌晨6点下午6点。有办法做到吗？

Answer 1

//@version=5
indicator("Custom Range Daily Volume", overlay = false)

start_hr = input.int(6, title = "Start hour")
end_hr = input.int(18, title = "End hour")

num_days = input.int(7, title = "Number of days")

var float[] daily_volumes = array.new_float()

var float todays_volume = 0.0

new_day = ta.change(time("D")) != 0

eod_time_close = request.security(syminfo.tickerid, "D", time_close, barmerge.gaps_off, barmerge.lookahead_on)

in_time_range = hour >= start_hr and hour < end_hr
is_eod = time_close == eod_time_close and barstate.isconfirmed

if new_day
    todays_volume := 0.0
else if in_time_range
    todays_volume += volume

if is_eod
    array.unshift(daily_volumes, todays_volume)
    if array.size(daily_volumes) > num_days
        array.pop(daily_volumes)

float daily_avg_vol = na
float repainting_avg_vol = na

if array.size(daily_volumes) == num_days
    daily_avg_vol := array.avg(daily_volumes)
    repainting_avg_vol := in_time_range ? (array.sum(daily_volumes) - array.get(daily_volumes, num_days - 1) + todays_volume) / num_days : na
plot(daily_avg_vol)
plot(fixnan(repainting_avg_vol), color = in_time_range ? color.yellow : color.gray, style = plot.style_circles)