在可执行文件中设置静态库

Question

我为我的CMAKE项目设置了以下设置：

add_executable(exeA ${SOURCES})
target_link_libraries(exeA PRIVATE libB)

libb 是A static 库在另一个项目中分别构建，并取决于共享 libraries LIBC 或 libd 提供等效的API，但以不同的方式实现并具有不同的性能配置文件。

在 exea 的构建中，我希望能够根据条件链接 libc libd 。

从阅读，看来我可以使用 rpath 相关的cmake属性，但是我是否可以使用这些属性来设置现有静态库的rpath

不幸的是，没有简单而快速的方法来改变一个 现有可执行文件或共享库。

在Cmake中可以做类似的事情吗？

感谢任何解决此用例的建议。

Answer 1

为 libb 和共享导入共享导入 libc libd libd libd libd libd libd libd libd 。将相关的一个放在 Interface_link_libraries libb 的属性中。构建 EXEA 时，Cmake将正确设置RPATH。

cmake_minimum_required(VERSION 3.23)
project(test)

# --------------------------------------------------
# The following code should probably be factored out
# into a proper Find module.

find_library(LIBB_LIBRARY NAMES B REQUIRED)
find_library(LIBC_LIBRARY NAMES C REQUIRED)
find_library(LIBD_LIBRARY NAMES D REQUIRED)

add_library(third-party::libC SHARED IMPORTED)
set_target_properties(
  third-party::libC
  PROPERTIES
  IMPORTED_LOCATION "${LIBC_LIBRARY}"
)

add_library(third-party::libD SHARED IMPORTED)
set_target_properties(
  third-party::libD
  PROPERTIES
  IMPORTED_LOCATION "${LIBD_LIBRARY}"
)

add_library(third-party::libB STATIC IMPORTED)
set_target_properties(
  third-party::libB
  PROPERTIES
  IMPORTED_LOCATION "${LIBB_LIBRARY}"
)

option(LIBB_USES_LIBC "dummy option for demo" ON)
if (LIBB_USES_LIBC)
  target_link_libraries(third-party::libB INTERFACE third-party::libC)
else ()
  target_link_libraries(third-party::libB INTERFACE third-party::libD)
endif ()

# --------------------------------------------------

# --------------------------------------------------
# Project code

add_executable(exeA main.cpp)
target_link_libraries(exeA PRIVATE third-party::libB)

您可以使用类似虚拟文件进行测试：

$ ls
CMakeLists.txt
$ mkdir -p prefix{1,2}/lib
$ touch prefix1/lib/lib{C,D}.so prefix2/lib/libB.a main.cpp
$ cmake -G Ninja -S . -B build "-DCMAKE_PREFIX_PATH=$PWD/prefix1;$PWD/prefix2"
-- The C compiler identification is GNU 9.4.0
-- The CXX compiler identification is GNU 9.4.0
-- Detecting C compiler ABI info
-- Detecting C compiler ABI info - done
-- Check for working C compiler: /usr/bin/cc - skipped
-- Detecting C compile features
-- Detecting C compile features - done
-- Detecting CXX compiler ABI info
-- Detecting CXX compiler ABI info - done
-- Check for working CXX compiler: /usr/bin/c++ - skipped
-- Detecting CXX compile features
-- Detecting CXX compile features - done
-- Configuring done
-- Generating done
-- Build files have been written to: /home/alex/test/build
$ cmake --build build -- -nv  # dry run (n), verbose (v)
[1/2] /usr/bin/c++    -MD -MT CMakeFiles/exeA.dir/main.cpp.o -MF CMakeFiles/exeA.dir/main.cpp.o.d -o CMakeFiles/exeA.dir/main.cpp.o -c /home/alex/test/main.cpp
[2/2] : && /usr/bin/c++   CMakeFiles/exeA.dir/main.cpp.o -o exeA  -Wl,-rpath,/home/alex/test/prefix1/lib  ../prefix2/lib/libB.a  ../prefix1/lib/libC.so && :

如您所见， rpath 已正确设置为包含 libc.so 的目录。