处理多个可选参数

Question

我有一个

f:=proc(x,option1,option2) ... end proc;

过程中的过程 option1 始终是整数， option2 是列表或其他内容（包括整数）。这两个选项都是可选的，因此这些命令可以按预期工作：

f(x);
f(x,3);
f(x,4,[1,2]);
f(x,5,3);
f(x,6,expand);

如果未指定 option1 ，那么我不知道一种简单的处理方法

f(x,,3);
f(x,,[1,2]);

但是， 让它理解，

f(x,[1,2]);

但我仍然有问题

f(x,3);

，因为尚不清楚 3 是 option1 或 option2 。我可以重写代码以以这种格式理解函数调用

f(x,[1,option1],[2,option2]);
f(x,[1,option1]);
f(x,[2,option2]);

，但是我很好奇是否有更简单的方法可以实现这一目标事情。

Answer 1

使用关键字参数。

f:=proc(x,{op1::integer:=0,op2::{list,integer}:={}},$)

   if has([_passed],'op1') then
      print("op1 =",op1);
   else
      print("op1 not passed");
   fi;

   if has([_passed],'op2') then
      print("op2 =",op2);
   else
      print("op2 not passed");
   fi;

    #rest of code
end proc;

您可以做到

f(x,'op2'=[1,2,3])    
                        "op1 not passed"    
                       "op2 =", [1, 2, 3]

和

f(x,'op1'=99)
                          "op1 =", 99
                        "op2 not passed"

并

f(x)
                        "op1 not passed"    
                        "op2 not passed"

确保

f(x,'op1'=99,'op2'=[1,2,3])
                          "op1 =", 99
                       "op2 =", [1, 2, 3]

现在，

f(x,'op1'=99,'op2'=19827)
                          "op1 =", 99
                         "op2 =", 19827

通话时使用'op1'= value ，而不是 op1 = value

Answer 2

正如其他人已经提到的那样，一种解决方案是使用“ kwarg ”（关键字参数）。您也可以使用 _经过或 _REST 。您可以在Maple帮助页面或Maple编程指南中阅读更多信息（）。

这只是一个示例，您可以如何使用它们。 _通过是为了说出已将其传递给您的过程的任何内容，而 _REST 是针对已将其传递给您的过程的任何内容到 proc 前面的括号内提到的参数。假设我们要定义一个具有1个必要参数的过程，并可能有2个可选的参数。如果给出了两个可选参数，我们假设第一个始终是 option1 ，第二个是 option2 ，但是如果给出一个可选参数，则根据是否它是类型 Integer 是否分别为 option1 或 option2 。

要询问传递的数量或通过的其余参数，您可以使用 _npassed 和 _NREST 。命令分配（）检查是否分配了一个值。您可以通过类型（ - ， - ）或 - :: - 检查是否是特定类型的东西。因此，这是简单的代码。

test := proc( x )
    local option1, option2:
    if _nrest = 2 then
        option1 := _rest[1]:
        option2 := _rest[2]:
    elif _nrest = 1 then
        if _rest[1] :: integer then
            option1 := _rest[1]:
        else
            option2 := _rest[1]:
        end if:
    end if:
    printf( "necessary argument is %a\n", x ):
    if assigned( option1 ) then
        printf( "option 1 is given and is %d\n", option1 ):
    end if:
    if assigned( option2 ) then
        printf( "option 2 is given and is %a\n", option2 ):
    end if:
end proc:

这是针对不同输入的上述过程的输出的屏幕截图。

Answer 3

大多数绘图命令都使用Maple更现代的管理过程选项。

特别是绘制命令的大多数选项都提供为SO-CALLED 关键字选项。这会自动提供（此类选项）的位置无关紧要的功能。

例如，

f:=proc(v, 
        {ord::{integer,NoUserValue}:=':-NoUserValue'},
        {special::{integer,list,NoUserValue}:=':-NoUserValue'});

  print(':-ord'=ord, ':-special'=special);

end proc:

f(x);

    ord = NoUserValue, special = NoUserValue

f(x,ord=3);

         ord = 3, special = NoUserValue

f(x,special=5);

         ord = NoUserValue, special = 5

f(x,special=5,ord=3);

               ord = 3, special = 5

f(x,ord=3,special=5);

               ord = 3, special = 5

正如您注意到的那样，[从逻辑上]您无法使用多个 *位置/有序的“如果两者都有相同的类型，并且丢失了一些类型

。 href =“ https://www.maplesoft.com/support/help/help/maple/view.aspx？path = argument_processing#positional” rel =“ nofollow noreferrer”> positional promotal参数，尽管自然会失去其灵活性例如，任意

restart;
f2:=proc(v, 
        ord::{integer,NoUserValue}:=':-NoUserValue',
        {special::{integer,list,NoUserValue}:=':-NoUserValue'});

  print(':-ord'=ord, ':-special'=special);

end proc:
f2(x);
f2(x,3);
f2(x,special=5);
f2(x,special=5,3);
f2(x,3,special=5);

restart;
f3:=proc(v, 
         special::{integer,list,NoUserValue}:=':-NoUserValue',
         {ord::{integer,NoUserValue}:=':-NoUserValue'});

  print(':-ord'=ord, ':-special'=special);

end proc:
f3(x);
f3(x,5);
f3(x,ord=3);
f3(x,ord=3,5);
f3(x,5,ord=3);

。

位置