MS项目在资源使用视图中导航资源和作业

Question

问候。我正在寻找VBA中的代码，该代码允许我在资源使用视图中使用for Next在ResourceField中进行分配的资源，并从TimesCalerange中提取他们的作业信息（右图带有表格信息），in为了能够格式化信息并在决策后导出。

捕获资源用法的捕获视图

我将关注的信息扩展了一点...在捕获中，我呈现资源使用视图，我获取这些信息，并在左侧使用资源列表，我将其复制并粘贴在Excel中；有了这些信息，我创建了我的资源直方图，但是我想通过VBA宏来生成导出过程，因为有几个步骤可以执行（过滤，组织视图的时间表以及导出开始到终点的信息）。

Answer 1

该代码将循环通过活动项目中的资源，并按每周逐日获取工作时间。

Sub GetWorkByResourceByAssignment()

    Dim dteStart As Date
    Dim dteEnd As Date

    dteStart = #5/24/2021#
    dteEnd = #8/2/2021#
    
    Dim res As Resource
    Dim a As Assignment
    Dim tsvs As TimeScaleValues
    Dim tsv As TimeScaleValue
    
    For Each res In ActiveProject.Resources
        For Each a In res.Assignments
    
            Set tsvs = a.TimeScaleData(StartDate:=dteStart, _
                                       EndDate:=dteEnd, _
                                       Type:=pjAssignmentTimescaledWork, _
                                       TimeScaleUnit:=pjTimescaleWeeks)
            ReDim workHours(tsvs.Count) As Long
            Dim strValues As String
            strValues = vbNullString
            Dim i As Integer
            i = 0
            For Each tsv In tsvs
                i = i + 1
                workHours(i) = Val(tsv.Value) / 60
                strValues = strValues & ", " & workHours(i)
            Next tsv
            Debug.Print res.Name, a.Task.Name, strValues
        Next
    Next
    
End Sub

变量strvalues和调试语句用于演示目的。数组workHours包含可用于直方图的小时的数字表示。