在SAS中迭代几个月

Question

我有以下问题。这样的表中每个实体有六个月的交易数据：

customer_1  1000  January
customer_1  1000  January
customer_1  1000  February
customer_1  1000  February
customer_1  1000  March
customer_1  1000  April
customer_1  1000  May
customer_1  1000  June

我想计算每两个月的交易数量，例如：

1月至2月有4个交易数量。 2月至3月有3次交易 等等。

我使用嵌套环尝试，以便定义一个开始日期和结束日期，然后在循环结束时我添加了1个月并再次迭代。这样的事情：

 do i = n to 1 by -1 while (date_key{i} >= begin_date);

        do k = i to 1 by -1 while(date_key{k} >= b_d and date_key{k} <= intnx('Month',b_d,2, 's'));

            if upcase(account{k}) in (&account_type) and
            then do;
                total_amount = sum(total_amount,currency_amount{k});
                amt_cnt = amt_cnt + 1;
            end;
        end;
        if total_amount >= threshold_total then m_cnt = sum(m_cnt,1);
        b_d = intnx('Month',b_d,1,'s');
 end;

Answer 1

您可能应该只使用多标签格式和支持它们的PROC。

首先，让我们创建一些实际的示例输入数据。

data have ;
  input id :$10. amount date :yymmdd.;
  format date yymmdd.;
cards;
customer_1  1001  2021-01-01
customer_1  1002  2021-01-01
customer_1  1003  2021-02-01
customer_1  1004  2021-02-01
customer_1  1005  2021-03-01
customer_1  1006  2021-04-01
customer_1  1007  2021-05-01
customer_1  1008  2021-06-01
;

然后，让我们创建一个示例格式。这是一种名为“命名期”的格式，是2021年的前5个两个月期。

proc format cntlout=formats;
 value periods (MULTILABEL)
   '01JAN2021'd -< '01MAR2021'd = '2021 01-02'
   '01FEB2021'd -< '01APR2021'd = '2021 02-03'
   '01MAR2021'd -< '01MAY2021'd = '2021 03-04'
   '01APR2021'd -< '01JUN2021'd = '2021 04-05'
   '01MAY2021'd -< '01JUL2021'd = '2021 05-06'
 ;
run;

一旦定义了格式，将其应用于您的日期变量，并按日期进行汇总。

这是使用Proc摘要的代码。

proc summary data=have nway;
  class date / mlf ;
  var amount;
  output out=want(rename=(date=period)) sum= ;
  format date periods.;
run;
proc print data=want;
run;

和结果：

对于一系列日期，动态制作格式并不难。您只需要数据集中的这些变量即可与cntlin = proc格式的选项一起使用。

也许这样的东西：

data cntlin;
  fmtname='PERIODS';
  sexcl='N';
  eexcl='Y';
  hlo='SM';
  length label $20 ;
  do offset=0 to intck('month','01JAN2021'd,'01JAN2022'd)-1;
    start = intnx('month','01JAN2021'd,offset);
    end = intnx('month',start,2);
    label=cat(put(start,yymmd7.),' and ',put(end-1,yymmd7.));
    output;
  end;
run;