我试图使用Arduino串行显示器接收输入

Question

我正在尝试制作一个简单的程序来打开和关闭激光器。它运行良好，直到我试图通过将2输入串行显示器来使其眨眼。它眨眼，但只有一次。我想做的就是永远眨眼，同时还等待用户输入某些东西以停止眨眼。这是我的代码。

int laserPin = 3; 
int laserState; 

void setup()
{
  pinMode(laserPin, OUTPUT);  // set pin10 as output pin
  digitalWrite(laserPin, LOW); // set the pin value on low at the begin
  Serial.begin(9600);
  Serial.println("     Commands");
  Serial.println("--------------------");
  Serial.println("2- makes laser blink");
  Serial.println("1- turns laser on");
  Serial.println("0- turns laser off");
}
void loop()
{
  Serial.println("Set laser state to: "); //Prompt User for Input
  while (Serial.available() == 0) {
    // Wait for User to Input Data
  }
  laserState = Serial.parseInt(); //Read the data the user has input
  Serial.println(laserState);
  if(laserState == 1){
    Serial.println("Turning laser on");
    digitalWrite(laserPin, HIGH);
    }
   else if(laserState == 0){
      Serial.println("Turning laser off");
      digitalWrite(laserPin, LOW);
   }
   else if(laserState == 2){
      Serial.println("Making laser blink");
      while(laserState == 2)
      {
        digitalWrite(laserPin, HIGH);
        delay(1000);
        digitalWrite(laserPin, LOW);
        Serial.println("Set laser state to: "); //Prompt User for Input
        laserState = Serial.parseInt(); //Read the data the user has input
      }
   }
}

这是我为激光闪烁的代码：

   else if(laserState == 2){
  Serial.println("Making laser blink");
  while(laserState == 2)
  {
    digitalWrite(laserPin, HIGH);
    delay(1000);
    digitalWrite(laserPin, LOW);
    Serial.println("Set laser state to: "); //Prompt User for Input
    laserState = Serial.parseInt(); //Read the data the user has input
  }

}

Answer 1

如果您想一次使Arduino做一个以上的事情，则需要让循环保持运行并跟踪状态 - 而不是在循环时保持循环。

我已经采用了您的代码并进行了稍微修改，以允许读取串行，并闪光激光。

在此版本中，laserstate通常设置为-1-这意味着循环每次检查串行输入都不会做任何事情。

当您输入串行INT时 - 这将更改laserstate，将执行适当的操作。

打开和关闭激光后，立即将Laserstate设置回-1，因此不会发生进一步的操作。

但是 - 如果laserstate将设置为2，则它将保持在每个环路迭代的值，并且激光将继续闪烁，直到收到另一个串行输入以更改状态。

还有一个标志可以确定何时显示提示（尽管每次LED闪烁时都会显示它）。

可以通过删除闪光灯中的延迟并使用millis（）来确定何时打开和关闭激光器来使这可以更快地响应 - 因此您不必等待闪存循环读取下一个串行输入 - 但这会更复杂。

int laserPin = 3; 
int laserState = -1; 
bool showPrompt = true ;

void setup()
{
  pinMode(laserPin, OUTPUT);  // set pin10 as output pin
  digitalWrite(laserPin, LOW); // set the pin value on low at the begin
  Serial.begin(9600);
  Serial.println("     Commands");
  Serial.println("--------------------");
  Serial.println("2- makes laser blink");
  Serial.println("1- turns laser on");
  Serial.println("0- turns laser off");
}
void loop()
{
  if ( showPrompt ) {
    Serial.println("Set laser state to: "); //Prompt User for Input
    showPrompt = false ;
  }
  if (Serial.available()) {
    // Read the User Input Data
    laserState = Serial.parseInt(); //Read the data the user has input
    Serial.println(laserState);
  }

  if(laserState == 1){
    Serial.println("Turning laser on");
    digitalWrite(laserPin, HIGH);
    laserState = -1 ; 
    showPrompt = true ;
  }
  else if(laserState == 0){
    Serial.println("Turning laser off");
    digitalWrite(laserPin, LOW);
    laserState = -1 ; 
    showPrompt = true ;
   }
   else if(laserState == 2){
     Serial.println("Making laser blink");
     digitalWrite(laserPin, HIGH);
     delay(1000);
     digitalWrite(laserPin, LOW);
     delay(1000);
     showPrompt = true ;
   }
}