如何计算第一个事件与SAS中的最后一个事件之间具有多个ID重复的时间？

Question

我有一个带有患者数据的数据集。我想计算患者首次拜访和最后一次去医院之间经过了多少天。我还需要一个虚拟变量（0,1），如果观察到数据集中的患者（根据访问日期），则采用该值1。数据集看起来像：

Patient ID  Visit date
1           2014-04-21
1           2015-01-29
1           2021-04-14
2           2020-01-03
2           2021-07-04
.           .
.           .

我想要的：

Patient ID  Visit date  First visit  Difference between first visit and last (in days)
1           2014-04-21  1            0
1           2015-01-29  0            283
1           2021-04-14  0            2550  
2           2020-01-03  1            0
2           2021-07-04  0            548
.           .           .             .
.           .           .             .

如果我按患者ID对数据集进行排序，然后访问日期并运行代码：如果First.PatientID，则进行； first_visit = 1; end;我能够创建我的虚拟变量。我在计算第一次访问和上次访问之间的天数方面遇到了麻烦。非常感谢任何帮助。谢谢！

Answer 1

您将需要保留一个新变量才能获得累积的日子。如果您使用sum语句，则会自动保留变量。如果使用dif（）函数在当前日期和上一个日期之间获得几天的差异，则可以保留天数本身，而不是需要保留实际的第一个日期值。

data have;
  input ID  DATE :yymmdd.;
  format date yymmdd10.;
cards;
1 2014-04-21
1 2015-01-29
1 2021-04-14
2 2020-01-03
2 2021-07-04
;

data want;
  set have;
  by id date;
  first_visit=first.id;
  days + dif(date);
  if first.id then days=0;
run;

几张笔记。

第一个。变量已经被编码为1/0，因此只需使用分配语句将其值保存到永久变量中即可。

请勿有条件运行DIF（）函数。这将跳过将当前日期添加到堆栈中以进行检索。这就是为什么您应该将dif（）添加到几天之前，然后将几天添加到零，以便对ID的第一个观察结果。

结果：

                           first_
Obs    ID          DATE     visit    days

 1      1    2014-04-21       1         0
 2      1    2015-01-29       0       283
 3      1    2021-04-14       0      2550
 4      2    2020-01-03       1         0
 5      2    2021-07-04       0       548

Answer 2

data WANT;
  set HAVE;
  by ID;
  first_visit = first.ID;
  retain firstDate;
  if first.ID then firstDate = Date;
  days = Date - firstDate;
  drop firstDate;
run;