Oracle：是否可以计算表数据中数据使用的实际存储大小？

Question

我希望能够报告表格中数据使用的实际存储量，以便例如我删除 n 。然后，我可以将数据删除工作的一行（作为数据删除工作的一部分），然后可以重新分析表存储量，以计算数据删除已释放的实际存储量。

我正在使用以下查询，但已经意识到这可能是将分配的存储空间返回到单个表段，而不是实际存储空间，该存储空间正在消耗数据：

SELECT 
     OWNER "SCHEMA"
    ,SEGMENT_NAME 
    ,SUM(BYTES) "TOTAL BYTES"
    ,SUM(BYTES/1024) "TOTAL KB (BINARY)"
    ,SUM((BYTES/1024)/1024) "TOTAL MB (BINARY)"
    ,ROUND(SUM(((BYTES/1024)/1024)/1024),6) "TOTAL GB (BINARY)" 
FROM dba_segments
WHERE 
    SEGMENT_TYPE = 'TABLE'
GROUP BY 
     OWNER
    ,SEGMENT_NAME
ORDER BY 
     OWNER 
    ,ROUND (SUM(((BYTES/1024)/1024)/1024),6) desc

oracle

例如，如果我从dba_tables视图中的“块”字段中获取统计数据，然后将其乘以我们分配的块大小（即8个字节），那是给我表的分配或实际数据量吗？

Answer 1

您可能想要基于 >过程。这将告诉您多少个街区，满是0-25％，满25-50％，满50-75％，并且已满75-100％，并且完全满。我在下面的脚本中使用中点估计值 - 如果您试图通过删除大量数据来确定要创建多少可用空间，则使用乐观或悲观的估计可能更有意义。您还需要针对任何索引，实现的视图等运行相同的过程，这将受到从表中删除数据的影响。

drop table foo;
/

create table foo (
  col1 number
);

insert into foo
  select level 
    from dual
 connect by level <= 10000;
 
declare
  l_unformatted_blocks integer;
  l_unformatted_bytes integer;
  l_fs1_blocks integer;
  l_fs1_bytes integer;
  l_fs2_blocks integer;
  l_fs2_bytes integer;
  l_fs3_blocks integer;
  l_fs3_bytes integer;
  l_fs4_blocks integer;
  l_fs4_bytes integer;
  l_full_blocks integer;
  l_full_bytes integer;
  l_partition_name varchar2(30) := null;
  l_segment_size integer;
begin
  select sum(bytes)
    into l_segment_size
    from user_segments
   where segment_name = 'FOO';

  dbms_space.space_usage( user, 'FOO', 'TABLE',
                          l_unformatted_blocks, l_unformatted_bytes,
                          l_fs1_blocks, l_fs1_bytes,
                          l_fs2_blocks, l_fs2_bytes,
                          l_fs3_blocks, l_fs3_bytes,
                          l_fs4_blocks, l_fs4_bytes,
                          l_full_blocks, l_full_bytes,
                          l_partition_name );
  dbms_output.put_line( 'Segment size is ' || l_segment_size || 
                        ' of which roughly ' || 
                        to_char( 
                          l_full_bytes + 
                          l_fs4_bytes * 0.125 + 
                          l_fs3_bytes * 0.375 + 
                          l_fs2_bytes * 0.625 +
                          l_fs1_bytes * 0.875
                        ) ||
                        ' bytes used ' ||
                        to_char( 
                          8 * 1024 *
                          l_full_blocks + 
                          l_fs4_blocks * 0.125 + 
                          l_fs3_blocks * 0.375 + 
                          l_fs2_blocks * 0.625 +
                          l_fs1_blocks * 0.875
                        ) ||
                        ' if we use blocks.' 
);
end;
/