XSLT从另一个节点选择属性

Question

这是我的XML文件：

<root>
    <headers>
        <header value="type1" />
        <header value="type3" />
        <header value="type2" />
    </headers>
    <data type1="data1_1" type2="data1_2" type3="data1_3" />
    <data type1="data2_1" type2="data2_2" type3="data2_3" />
</root>

我想生成CSV，仅在标题部分中列出标题。这是我的XSLT文件：

<?xml version="1.0" encoding="UTF-16"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" indent="no" encoding="unicode" />
<xsl:template match="root">
     <xsl:apply-templates/>
</xsl:template>


<xsl:template match="headers">
    <xsl:apply-templates/><xsl:text>&#xa;</xsl:text>
</xsl:template>


<xsl:template name="separator">
    <xsl:text>&#x09;</xsl:text>
</xsl:template>

<!-- display first line header work ok -->
<xsl:template match="header">
    <xsl:value-of select="@value" />
    <xsl:if test="position() != last()">
      <xsl:call-template name="separator" />
   </xsl:if>
</xsl:template>


<xsl:key name="mykey" match="header" use="@value" />

<!-- For each data parameters check if exist in header and display with the good order ! NOT WORK -->
<xsl:template match="data">
    <xsl:for-each select="@*">
        <xsl:if test="key('mykey', name())">
            <xsl:value-of select="." />
            <xsl:if test="position() != last()">
                <xsl:call-template name="separator" />
            </xsl:if>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

我想要此输出格式（CSV）：

type1 type3 type2
data1_1 data1_3 data1_2
data2_1 data2_3 data2_2

但是我的输出是（数据Type2不在正确的标题下）：

type1 type3 type2
data1_1 data1_2 data1_3
data2_1 data2_2 data2_3

Answer 1

我会简单地做：

xslt 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:template match="/root">
    <xsl:variable name="headers" select="headers/header" />
    <!-- header -->
    <xsl:for-each select="$headers">
        <xsl:value-of select="@value"/>
        <xsl:if test="position()!=last()">
            <xsl:text>	</xsl:text>
        </xsl:if>
    </xsl:for-each>
    <xsl:text>
</xsl:text>
    <!-- data -->
    <xsl:for-each select="data">
        <xsl:variable name="data" select="." />
        <xsl:for-each select="$headers">
            <xsl:value-of select="$data/@*[name()=current()/@value]"/>
            <xsl:if test="position()!=last()">
                <xsl:text>	</xsl:text>
            </xsl:if>
        </xsl:for-each> 
        <xsl:text>
</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

---

替代（也许更有效），您可以做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:key name="data-value" match="data/@*" use="concat(name(), '|', generate-id(..))" />

<xsl:template match="/root">
    <xsl:variable name="headers" select="headers/header" />
    <!-- header -->
    <xsl:for-each select="$headers">
        <xsl:value-of select="@value"/>
        <xsl:if test="position()!=last()">
            <xsl:text>	</xsl:text>
        </xsl:if>
    </xsl:for-each>
    <xsl:text>
</xsl:text>
    <!-- data -->
    <xsl:for-each select="data">
        <xsl:variable name="data-id" select="generate-id()" />
        <xsl:for-each select="$headers">
            <xsl:value-of select="key('data-value', concat(@value, '|', $data-id))"/>
            <xsl:if test="position()!=last()">
                <xsl:text>	</xsl:text>
            </xsl:if>
        </xsl:for-each> 
        <xsl:text>
</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

---

btw，结果是一个选项卡分离的文件，而不是CSV 。

Answer 2

属性没有设置顺序。元素可以。因此，让我们使用这些元素提供您的订购：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" indent="no" encoding="unicode" />
<xsl:template match="Results">
     <xsl:apply-templates/>
</xsl:template>

<xsl:template match="headers">
    <xsl:apply-templates/><xsl:text>
</xsl:text>
</xsl:template>

<xsl:template name="separator">
    <xsl:text>	</xsl:text>
</xsl:template>

<!-- display first line header work ok -->
<xsl:template match="header">
    <xsl:value-of select="@value" />
    <xsl:if test="position() != last()">
      <xsl:call-template name="separator" />
   </xsl:if>
</xsl:template>

<!-- Use the order of the headers to choose the order of the attributes. -->
<xsl:template match="data">
    <xsl:variable name="data" select="."/>
    <xsl:for-each select="/root/headers/header">
        <xsl:value-of select="$data/@*[name()=current()/@value]"/>        
            <xsl:if test="position() != last()">
                <xsl:call-template name="separator" />
            </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

输出：

    type1   
    type3   
    type2   


data1_1 data1_3 data1_2
data2_1 data2_3 data2_2

标题在单独的行上，因为我没有更改代码的那一部分。

Answer 3

1. 为文本（）节点创建一个模板，以摆脱元素（新行，凹痕）之间的所有文本，
2. 这是您的XSLT之间的新线，

这是您的XSLT，其中XSLT的次要修复程序可以执行您想要的工作：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    
    <xsl:output method="text" indent="no" encoding="unicode" />
    
    <xsl:template match="root">
        <xsl:apply-templates/>
    </xsl:template>
            
    <xsl:template match="headers">
        <xsl:apply-templates/><xsl:text>
</xsl:text>
    </xsl:template>
    
    <xsl:template match="text()"></xsl:template>
    
    <xsl:template name="separator">
        <xsl:text> </xsl:text>
    </xsl:template>
    
    <!-- display first line header work ok -->
    <xsl:template match="header">
        <xsl:value-of select="@value" />
        <xsl:if test="position() != last()">
            <xsl:call-template name="separator" />
        </xsl:if>
    </xsl:template>
    
    
    <xsl:key name="mykey" match="header" use="@value" />
    
    <!-- For each data parameters check if exist in header and display with the good order ! NOT WORK -->
    <xsl:template match="data">
        <xsl:for-each select="@*">
            <xsl:if test="key('mykey', name())">
                <xsl:value-of select="." />
                <xsl:choose>
                    <xsl:when test="position() != last()">
                        <xsl:call-template name="separator" />
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:text>
</xsl:text>
                    </xsl:otherwise>
                </xsl:choose>
                
            </xsl:if>
        </xsl:for-each>
    </xsl:template>
    
</xsl:stylesheet>