设置代码的方法是什么，以便在A列中查找最后一个填充的行，然后消除列H具有值= 0的行？

Question

早上好，

目前，我有此代码可以删除行没有到期日（J列）和付款金额= 0（H列）。

Sub delete_rows()

Range("A1").End(xlDown).Select
    
Sheets("AA").Select
Range("J2").Select
ActiveCell.FormulaR1C1 = "=IF(RC[-5]=0,"""",RC[-5])"
Range("J2").Select
Selection.AutoFill Destination:=Range("J2:J500"), Type:=xlFillDefault
Range("J2").End(xlDown).Select
Range("K2").Select

Application.ScreenUpdating = False
With Sheet2
 For line = .Cells(.Rows.Count, "J").End(xlUp).Row To 2 Step -1
   If .Cells(line, "J") = "" Then
     .Rows(line).Delete
   End If
 Next linha
End With
Application.ScreenUpdating = True

ActiveCell.FormulaR1C1 = "=IF(RC[-4]="""","""",RC[-4])"
Range("K2").Select
Selection.AutoFill Destination:=Range("K2:K500"), Type:=xlFillDefault
Range("K2").End(xlDown).Select
Range("J1").Select

Application.ScreenUpdating = False
With Sheet2
 For line = .Cells(.Rows.Count, "K").End(xlUp).Row To 2 Step -1
   If .Cells(line, "K") = "" Then
     .Rows(line).Delete
   End If
 Next line
End With
Application.ScreenUpdating = True
End sub()

我创建了一个具有定义数量的代码...但是，该代码运行需要很长时间，因为有时行数很少，并且总是运行500行。设置代码的方法是什么，以便它在A列中查找最后一个填充的行，然后消除列H具有值= 0的行，而列j n no值中的行？

Answer 1

请检查：找到最后一个单元格a>。还请查看：避免选择。

之后，我认为您应该能够理解以下代码，这应该为您带来所需的结果：

Sub test()

Application.ScreenUpdating = False

'declare your variables
Dim ws As Worksheet
Dim Rng1 As Range, Rng2 As Range
Dim i As Long, lastRow As Long

Set ws = Sheets("AA")

With ws

    'get last row in
    lastRow = .Range("A" & .Rows.Count).End(xlUp).Row
    
    'set ranges for loop
    Set Rng1 = Range(.Cells(2, "H"), .Cells(lastRow, "H"))
    Set Rng2 = Range(.Cells(2, "J"), .Cells(lastRow, "J"))
    
    'reverse loop
    For i = Rng1.Rows.Count To 1 Step -1

        'check conditions for cell in "H" and "J"
        If Rng1.Cells(i) = 0 And Rng2.Cells(i) = "" Then
        
            'defined ranges start at row 2, hence +1
            ws.Rows(i + 1).Delete
        
        End If

    Next i
    
End With

Application.ScreenUpdating = True

End Sub