递增序言中的计数器

Question

这是我正在处理的问题的当前代码。它应该从文件中读取，并每次遇到元音时，将计数器（r）添加。 目前，我在到达元音时停止了，但是我希望它增加计数器，然后继续处理。完成后，我希望它将R打印到控制台。提前致谢！

readWord(InStream, W) :-
        get0(InStream,Char),
        checkChar_readRest(Char,Chars,InStream, R),
        atom_codes(Code,Chars),
        write(Code).

%checkChar_readRest(10,[],_) :- !. % Return
%checkChar_readRest(32,[],_) :- !. % Space
checkChar_readRest(-1,[],_,_) :- !. % End of Stream
checkChar_readRest(97,[],_,R) :- !. % a
checkChar_readRest(101,[],_,R) :- !. % e
checkChar_readRest(105,[],_,R) :- !. % i
checkChar_readRest(111,[],_,R) :- incr(R,R1), write(R1). % o
checkChar_readRest(117,[],_,R) :- !. % u
%checkChar_readRest(end_of_file,[],_,_) :- !.
checkChar_readRest(Char,[Char|Chars],InStream,R) :-
    get0(InStream,NextChar),
    checkChar_readRest(NextChar,Chars,InStream,R).

incr(X, X1) :- X1 is X+1.

vowel(InStream, R) :- 
    open(InStream, read, In), 
    repeat,
    readWord(In, W),
    close(In).

Answer 1

这是我的尝试（ISO谓词）：

% open Src, count vowels, close stream, print to console
count_vowels_in(Src) :-
    open(Src, read, Stream),
    count(Stream, Total),
    close(Stream),
    % cutting here because our Stream is now closed, any backtracking will break things that rely on it
    % you could also put this after at_end_of_stream/1 in count_/3
    % not sure what best practices are here
    !,
    write(Total).

% just a nice wrapper to get started counting with the initial count set to 0
count(Stream, Total) :-
    count_(Stream, 0, Total).

% at end of stream, Count = Total and we're done
count_(Stream, Count, Count) :-
    at_end_of_stream(Stream).

% read from stream recursively, incrementing Count as needed
count_(Stream, Count0, Total) :-
    \+at_end_of_stream(Stream),
    get_char(Stream, Char),
    char_value(Char, Value),
    Count1 is Count0 + Value,
    % recursively call count_, but now with our new Count1 value instead, carrying forward the results
    count_(Stream, Count1, Total).

char_value(Char, 1) :-
    vowel(Char).
char_value(Char, 0) :-
    \+vowel(Char).

vowel(a).
vowel(e).
vowel(i).
vowel(o).
vowel(u).

最大的区别是我使用两个变量来跟踪计数。 count（等效于您的r）是当前计数，total是代表最终计数的变量。我们将与count统一在我们完成计数时：在流的末尾。

在发布的原始程序中，有许多Singleton变量（变量永远不会与任何内容统一，例如w）。这通常表示错误，并会引起警告。还记得Prolog是一种逻辑语言，退后一步并认为“我实际上试图用这些变量来做些什么？”。它还可以帮助将问题分解为较小的块，而不是试图编写一个可以完成所有操作的谓词。

Answer 2

我可能会这样处理：

• 整个文件中的slurp作为字符列表。
• 遍历该列表，并将其包含的元音计数。
• 写塔利。

类似的东西

findall(C, ( get0(V) , V \= -1 , char_code(C,V) ), Cs).

应该足以使文字含糊。

然后，沿着这些界线：

count_vowels :-
    findall(C, ( get0(V) , V \= -1 , char_code(C,V) ), Cs),
    count_vowels(Cs,N),
    writeln( total_vowels : N )
    .

count_vowels( S  , N ) :- string(S), !, string_chars(S,Cs), count_vowels(Cs,N) .
count_vowels( Cs , N ) :- count_vowels(Cs,0,N) .

count_vowels( []     , N , N ) .
count_vowels( [C|Cs] , T , N ) :- tally(C,T,T1), count_vowels(Cs,T1,N).

tally( C , M , N ) :- vowel(C), !, N is M+1 .
tally( _ , N , N ) .

vowel( a ).
vowel( e ).
vowel( i ).
vowel( o ).
vowel( u ).