您如何将不同尺寸的图像与一个图像的大小相结合，而尺寸为2？

Question

某些上下文

我正在从事体素游戏（例如Minecraft）的 。我无法使用预建的纹理地图集，因为我需要允许玩家在游戏中添加自定义块。这就是为什么我必须根据所提供的纹理在运行时创建纹理地图集的原因。这些纹理的尺寸不一定（一个可以是16 x 16，而另一个可以是64 x 64），所以我不能只在常规距离上粘贴图像。

实际问题

我如何结合多个图像，这些图像可以将不同的大小分解为一个，而我可以尽可能多地填充图像，以及图像应尽可能密集地包装，并且如果可以将图像放在最终图像上的较小位置应该放置在那里，以免使用其他图像可能使用的空间。 最终图像必须是一个正方形，其大小必须是2的最小功率。例如，如果有4 x 16张图像，则只能创建一个32 x 32映像，足以包含这些图像。但是说有5张图像，它应该创建一个64 x 64张图像，因为它的最小尺寸可以包含这些图像。 我还需要可以将其映射到区块的纹理的UV值。

游戏引擎我使用的

是我使用Godot游戏引擎。

Answer 1

输入

让我们说您有一系列image要放入纹理地图集。我们说这是一个数组：

var images:Array

该数组的值可以是：

• 将图像文件导入为image。
• 从get_data on 纹理>纹理 s获取。
• 图像在运行时通过其他方式创建的。

---

现在编译尺寸

，我们可以得到它们的尺寸。我们将在poolvector2array中需要它们（我们实际上可以在常规array中获取它们并进行转换，但是没有必要执行此操作）：

var sizes:PoolVector2Array
for image in images:
    sizes.append(image.get_size())

---

计算Atlas

一旦有尺寸，我们就可以调用geome.make_atlas：

var atlas_data := Geometry.make_atlas(sizes)

geemoge.make_atlas的算法将尝试制作Atlas Square。

我们应该查询我们得到的大小：

var min_atlas_size:Vector2 = atlas_data.size

可悲的是，戈多不会暴露“ 2”功能的“下一个力量”。在上下文的情况下，我相信一个简单的循环在这种情况下会做得很好：

var atlas_size := 16
while min_atlas_size.x > atlas_size or min_atlas_size.y > atlas_size:
    atlas_size *= 2

---

构建Atlas

创建一个Atlas image

现在我们已经确定了大小，我们可以创建一个新的图像用于地图集：

var atlas := Image.new() 
atlas.create(atlas_size, atlas_size, true, Image.FORMAT_RGBA8)

您可能会怀疑前两个参数是width和height。第三个参数是您是否要生成MIPMAP。最后一个是像素格式，我在这里选择的格式有四个通道（红色，绿色，蓝色，alpha），分别为8位（颜色深度）。

---

将输入图像 s复制到地图集图像

现在将原始图像复制到地图集。我们在从make_atlas中获得的结果获得每个位置：

var points:PoolVector2Array = atlas_data.points
for index in images.size():
    var image:Image = images[index]
    var point:Vector2 = points[index]
    var size:Vector2 = image.get_size()
    atlas.blit_rect(image, Rect2(Vector2.ZERO, size), point)

这是rect2是image> image我们要绘制的区域（所有）。

注意根据要绘制的image的格式，您可能必须先转换它：

source.convert(Image.FORMAT_RGBA8)

而且，通常，图像以压缩格式导入，无法为直接转换，因此您必须首先解压缩：

source.decompress()
source.convert(Image.FORMAT_RGBA8)

如果BLIT_RECT行给您问题，请尝试一下。

---

UV坐标

顺便说一句，您说要紫外线坐标，我们应该从相同的循环中获取它们：

var points:PoolVector2Array = atlas_data.points
var uv_scale := 1.0/atlas_size
var uv_rects := []
for index in images.size():
    var image:Image = images[index]
    var point:Vector2 = points[index]
    var size:Vector2 = image.get_size()
    atlas.blit_rect(image, Rect2(Vector2.ZERO, size), point)
    uv_rects.append(Rect2(point * uv_scale, size * uv_scale))

---

转换为纹理，

并且由于您想要紫外线坐标，我认为这是对于某些着色器，将成为纹理。因此，让我们做一个纹理：

var texture_atlas := ImageTexture.new()
texture_atlas.create_from_image(atlas)

然后您应该能够将其设置在需要的地方。我把它留给你。