语法为布尔人，为0和1

Question

我正在尝试用Antlr4制作小语法。我目前正在从事逻辑操作。要求之一是布尔值可以是'true | 1'或'false | 0'。

我面临的问题是算术操作。我也使用数字，因此，根据我的语法将“ 1”和“ 0”视为数字或布尔值的优先级。

将“ 0”和“ 1”作为布尔值并将其用作数字值也可以吗？

这是我目前的语法：

program: statement*;

statement: declaration | assignment | print;

print: PRINT (expression | condition);

declaration: VAR ID;

assignment: ID ASSIGN (expression | condition);

condition:    condition lo condition    #conditionCondition
            | expression lo expression  #expressionCondition
            | LP condition RP           #parenthesisCondition
            | boolean                   #booleanCondition
            | ID                        #idCondition;

expression:   SUB expression                                #subExpression
            | expression operator=(MUL | DIV) expression    #muldivExpression
            | expression operator=(ADD | SUB) expression    #addsubExpression
            | LP expression RP                              #parenthesisExpression
            | NUMBER                                        #numberExpression
            | ID                                            #idExpression;

boolean: TRUE | FALSE;

lo: GREATHER | LESSER | GREATEQUAL | LESSEQUAL | AND | OR | EQUAL | DIFFERENT;

//GROUP CHARATERS
LP: '(';
RP: ')';

//ARITHMETIC OPERATORS
MUL: '*';
DIV: '/';
ADD: '+';
SUB: '-';

//LOGIC OPERATORS
GREATHER: '>';
LESSER: '<';
GREATEQUAL: '>=';
LESSEQUAL: '<=';
AND: '&&';
OR: '||';
EQUAL: '==';
DIFFERENT: '!=';

//RESERVED WORDS
VAR: 'var';
PRINT: 'print';

ASSIGN: '=';

//VALUES
NUMBER: [0-9]+;
TRUE: '1' | 'true';
FALSE: '0' | 'false';

ID: [a-zA-Z]+[a-zA-Z0-9]*;

BLANKS: [ \t\r\n] -> skip;

Answer 1

您不能有两个规则匹配相同的输入。如果您指定多个，则语法中的第一个规则将始终匹配。

但是您可以做类似的事情：

ONE: '1';
ZERO: '0';
TRUE: 'true';
FALSE: 'false';
NUMBER: (ONE | ZERO)? [0-9]+;

boolean: TRUE | FALSE | ONE | ZERO;

Answer 2

我解决了它，将数字Lexer规则添加到条件解析器规则中。

condition:    condition lo condition    #conditionCondition
            | expression lo expression  #expressionCondition
            | LP condition RP           #parenthesisCondition
            | boolean                   #booleanCondition
            | NUMBER                    #numberCondition
            | ID                        #idCondition;

因此，从方法数字条件中，我检查数字值并根据需要返回布尔值。

我不知道这是否是最好的方法，但它可以解决我的问题。